# This is the region of the primary bucket and most other components
provider "aws" {
  region = var.aws_region
}

# This is the region of the failover bucket
provider "aws" {
  region = var.aws_failover_region
  alias  = "failover"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/frontend-documents/sme/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-orcd-cloudfront-waf-block"
  scope = "CLOUDFRONT"
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47: Disable rule as introducing suggested changes would block legitimate traffic
  # checkov:skip=CKV_AWS_374: Ensure AWS CloudFront web distribution has geo restriction enabled.
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.4.1"
  providers = {
    aws.primary  = aws
    aws.failover = aws.failover
  }

  environment           = var.environment
  service_name          = var.service_name
  application_family    = var.application_family
  brand                 = var.brand
  domain_name           = var.domain_name
  custom_logging_bucket = var.cloudfront_logging_bucket
  default_root_object   = "index-${var.brand}.html"
  additional_aliases    = ["${var.service_name}.${var.domain_name}"]
  custom_waf_name       = data.aws_wafv2_web_acl.waf.name
  # Pick two buckets in different regions. In qa/prod these values do not typically need to be specified.
  custom_origin_primary_s3_bucket_name  = "${var.environment}-orcd-cdn"
  custom_origin_failover_s3_bucket_name = "${var.environment}-orcd-cdn-us-west01"
}

data "cloudflare_zone" "cloudflare_cloudflare_zone" {
  name = var.domain_name
}

resource "cloudflare_record" "sme_documents_cloudflare_record" {
  zone_id = data.cloudflare_zone.cloudflare_cloudflare_zone.id
  name    = var.service_name
  ttl     = 1
  value   = module.spa_environment.cloudfront_distribution_domain_name
  type    = "CNAME"
  proxied = true
 }