# This is the region of the primary bucket and most other components
provider "aws" {
  region = "us-east-1"
}

# This is the region of the failover bucket
provider "aws" {
  region = "us-west-2"
  alias  = "failover"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/frontend-moneyhub/knr/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_route53_zone" "domain" {
  name         = var.domain_name
  private_zone = false
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-${var.brand}-waf-block"
  scope = "CLOUDFRONT"
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47: Disable rule as introducing suggested changes would block legitimate traffic

  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.3.0"
  providers = {
    aws.primary  = aws
    aws.failover = aws.failover
  }

  environment           = var.environment
  service_name          = var.service_name
  application_family    = var.application_family
  brand                 = var.brand
  domain_name           = var.domain_name
  custom_logging_bucket = "prod-orcd-cloudfront-logs"
  default_root_object   = "index-knr.html"
  custom_waf_name       = data.aws_wafv2_web_acl.waf.name
  # Pick two buckets in different regions. In qa/prod these values do not typically need to be specified.
  custom_origin_primary_s3_bucket_name  = "${var.environment}-orcd-cdn"
  custom_origin_failover_s3_bucket_name = "${var.environment}-orcd-cdn-us-west01"
}

resource "aws_route53_record" "route53_record" {
  name    = var.service_name
  zone_id = data.aws_route53_zone.domain.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [module.spa_environment.cloudfront_distribution_domain_name]
}