provider "aws" {
  region = var.aws_region
}

provider "aws" {
  alias  = "aws_us_west_2"
  region = "us-west-2"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/frontend-publishing/awal/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_route53_zone" "domain" {
  name         = var.domain_name
  private_zone = false
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-${var.service_name}-waf-block"
  scope = "CLOUDFRONT"
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.3.0"
  providers = {
    aws.primary = aws
    aws.failover = aws.aws_us_west_2
  }

  environment           = var.environment
  service_name          = var.service_name_suffix
  application_family    = var.application_family
  brand                 = var.service_name
  domain_name           = var.domain_name
  default_root_object   = "index-awal.html"
  additional_aliases    = ["${var.service_name_suffix}.${var.domain_name}"]
  custom_logging_bucket = var.custom_logging_bucket
  custom_waf_name       = data.aws_wafv2_web_acl.waf.name
}

resource "aws_route53_record" "route53_record" {
  name    = var.service_name_suffix
  zone_id = data.aws_route53_zone.domain.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [module.spa_environment.cloudfront_distribution_domain_name]
}