provider "aws" {
  region = var.region
}

provider "aws" {
  alias  = "aws_us_west_2"
  region = "us-west-2"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/frontend-royalties/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "frontend_royalties_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = "frontend-${var.service_name_suffix}"
  application_family = var.application_family
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-${var.service_name}-cloudfront-waf-block"
  scope = "CLOUDFRONT"
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  # checkov:skip=CKV_AWS_374:Ensure AWS CloudFront web distribution has geo restriction enabled.
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.4.1"
  providers = {
    aws.primary  = aws
    aws.failover = aws.aws_us_west_2
  }
  environment           = var.environment
  service_name          = var.service_name_suffix
  application_family    = var.application_family
  brand                 = var.service_name
  domain_name           = var.domain_name
  custom_s3_origin_path = "/frontend-royalties"
  default_root_object   = "index.html"
  additional_aliases = [
    "${var.service_name_suffix}.${var.domain_name}",
  ]
  custom_logging_bucket           = var.cloudfront_logging_bucket
  custom_waf_name                 = data.aws_wafv2_web_acl.waf.name
  response_headers_policy_enabled = false
}