provider "aws" {
  region = var.aws_region
}

provider "aws" {
  alias  = "failover"
  region = "us-west-2"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/frontend-settings/sme/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-orcd-cloudfront-waf-block"
  scope = "CLOUDFRONT"
}

module "spa_environment" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.1.0"
  providers = {
    aws.primary = aws
    aws.failover = aws.failover
  }

  environment                           = var.environment
  service_name                          = var.service_name
  application_family                    = var.application_family
  brand                                 = var.brand
  domain_name                           = var.domain_name
  custom_logging_bucket                 = "prod-orcd-cloudfront-logs"
  default_root_object                   = "index-sme.html"
  additional_aliases                    = ["settings.qapdesuite.com"]
  custom_waf_name                       = data.aws_wafv2_web_acl.waf.name
  # Pick two buckets in different regions. In qa/prod these values do not typically need to be specified.
  custom_origin_primary_s3_bucket_name  = "${var.environment}-orcd-cdn"
  custom_origin_failover_s3_bucket_name = "${var.environment}-orcd-cdn-us-west01"
}

data "cloudflare_zone" "cloudflare_cloudflare_zone" {
  name = var.domain_name
}

resource "cloudflare_record" "qa_sme_settings_cloudflare_record" { 
   zone_id = data.cloudflare_zone.cloudflare_cloudflare_zone.id 
   name    = var.service_name
   ttl     = 1 
   value   = module.spa_environment.cloudfront_distribution_domain_name
   type    = "CNAME"
   proxied = true 
 }