data "aws_secretsmanager_secret" "datadog_api" {
  name = "${var.environment}/datadog/DD_API_KEY"
}

data "aws_secretsmanager_secret_version" "datadog_api" {
  secret_id = data.aws_secretsmanager_secret.datadog_api.id
}

data "aws_secretsmanager_secret" "datadog_app_key" {
  name = "${var.environment}/datadog/DD_APP_KEY"
}

data "aws_secretsmanager_secret_version" "datadog_app_key" {
  secret_id = data.aws_secretsmanager_secret.datadog_app_key.id
}

# Datadog provider
provider "datadog" {
  api_key = data.aws_secretsmanager_secret_version.datadog_api.secret_string
  app_key = data.aws_secretsmanager_secret_version.datadog_app_key.secret_string
}

resource "datadog_monitor" "qa_lambda_gda_account_creation_error_monitor" {
  name    = "${var.environment}-lambda-gda-account-creation-error-monitor"
  type    = "query alert"
  message = "[${var.environment}] gda-account-creation lambda error monitor detected abnormal activity. Notify: ${var.notification_endpoints}"

  query = "avg(last_1w):anomalies(sum:aws.lambda.errors{env:${var.environment} AND (service_name IN (${join(",", var.lambda_function_names)}))} by {service_name}.as_count(), 'agile', 2, direction='above', interval=3600, alert_window='last_1d', count_default_zero='true', seasonality='daily', timezone='utc') >= 0.1"
  monitor_thresholds {
    critical = 0.1
  }
  notify_no_data      = false
  notify_audit        = false
  renotify_interval   = 60
  timeout_h           = 0
  require_full_window = false

  tags = [
    "environment:${var.environment}",
    "service_name:${var.service_name}",
    "application_family:${var.application_family}"
  ]
}

resource "datadog_monitor" "kafka_connector_dlq_monitor" {
  name    = "${var.environment}-${var.service_name}-failure-dlq-monitor"
  type    = "metric alert"
  message = "[${var.environment}] GDA Account Creation sent a message into ${var.monitor_dlq_topic_name}. Notify: ${var.notification_endpoints}"

  query = "max(last_1m):avg:aws.kafka.messages_in_per_sec{cluster_name:${var.trigger_msk_cluster_name},topic:${lower(var.monitor_dlq_topic_name)}} >= 1"

  monitor_thresholds {
    critical = 1
  }

  notify_no_data      = false
  notify_audit        = false
  renotify_interval   = 60
  timeout_h           = 0
  require_full_window = false

  tags = [
    "environment:${var.environment}",
    "service_name:${var.service_name}",
    "application_family:${var.application_family}"
  ]
}