# State machine lambda policy that gives the state machine role permission to invoke lambdas
data "aws_iam_policy_document" "lambda_gda_spotify_scraper_invoke_lambda_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_gda_spotify_scraper.lambda_arn,
    ]

  }
}

# Invoke lambda policy
resource "aws_iam_policy" "lambda_gda_spotify_scraper_invoke_lambda_policy" {
  name   = "${var.environment}-lambda-gda-spotify-scraper-invoke-policy"
  policy = data.aws_iam_policy_document.lambda_gda_spotify_scraper_invoke_lambda_policy_document.json
}

# Assume role policy used by Jenkins pipeline agent role
data "aws_iam_policy_document" "lambda_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# Jenkins pipeline agents will assume this role in order to invoke the lambda
resource "aws_iam_role" "jenkins_lambda_invoke_role" {
  name               = "${var.environment}-lambda-gda-score-calculation-integration-tests"
  assume_role_policy = data.aws_iam_policy_document.lambda_assume_role_policy.json
}


# Attach lambda invoke policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "lambda_gda_spotify_scraper_invoke_lambda_policy_attachment" {
  role       = aws_iam_role.jenkins_lambda_invoke_role.id
  policy_arn = aws_iam_policy.lambda_gda_spotify_scraper_invoke_lambda_policy.arn
}