data "aws_iam_policy_document" "lambda-gda-score-calculation-integration-test-secrets-policy-doc" {
  statement {
    effect = "Allow"
    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/datadog/",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/datadog/*",
    ]

    actions = [
      "secretsmanager:ListSecretVersionIds",
      "secretsmanager:GetSecretValue",
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:DescribeSecret"
    ]
  }
  statement {
    effect    = "Allow"
    resources = ["*"]
    actions   = ["secretsmanager:GetRandomPassword"]
  }
}

# Assume role policy used by Jenkins pipeline agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# Secrets manager policy.
resource "aws_iam_policy" "lambda-gda-score-calculation-integration-test-secrets-policy" {
  name   = "lambda-${var.environment}-gda-score-calculation-integration-test-secrets-policy"
  policy = data.aws_iam_policy_document.lambda-gda-score-calculation-integration-test-secrets-policy-doc.json
}

# Jenkins agents will assume this role in order to invoke the function
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "${var.environment}-lambda-gda-score-calculation-integration-test"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Attach lambda invoke policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "lambda_gda_score_calculation_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.lambda-gda-score-calculation-integration-test-secrets-policy.arn
}