module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/graphql-abacus/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io."
}

module "graphql_abacus_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.region
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 1024
  task_memory                              = 2048
  maximum_capacity                         = 4
  minimum_capacity                         = 2
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  application_family                       = var.application_family
  http_listener_enabled                    = false
  blocking_waf_enabled                     = true

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  iam_managed_policy_attachments = concat(
    [for policy in data.aws_iam_policy.existing_policies_to_attach : policy.arn]
  )

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      NODE_ENV = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      APOLLO_INTROSPECTION = "true"
    },
    {
      APOLLO_PLAYGROUND = "true"
    },
    {
      DD_LOGS_INJECTION = true
    },
    {
      NEO4J_URL = var.neo4j_url
    },
    {
      S3_PAYMENTS_BUCKET_NAME = var.s3_payments_bucket_name
    },
    {
      BUCKET_UPLOAD_ROLE_ARN = aws_iam_role.graphql_abacus_browser_upload_role.arn
    },
    {
      S3_ADJUSTMENTS_BUCKET_NAME = var.s3_adjustments_bucket_name
    },
    {
      BUCKET_UPLOAD_TOKEN_DURATION = var.bucket_upload_token_duration
    },
    {
      BEDROCK_REGION = "us-east-1"
    },
    {
      CORS_ORIGIN = "https://abacus.qaorch.com"
    },
    {
      REDIS_URL = module.graphql_abacus_chatbot_cache.redis_primary_endpoint_address
    }
  ]

  secrets = [
    {
      SPLIT_API_KEY = "${var.environment}/split/API_KEY"
    }
  ]
}

module "graphql_abacus_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.16.0"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  notification_endpoints            = "@slack-monitoring @slack-graphql"
  escalation_notification_endpoints = "@slack-graphql"
  datadog_service_type              = "${var.service_name}-graphql"
  datadog_service_name              = "graphql.execute"
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = false
}

module "sentry-graphql-abacus" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = var.service_name
  teams              = ["abacus-${var.environment}"]
  application_family = var.application_family
}

data "aws_s3_bucket" "graphql_abacus_payments_bucket" {
  bucket = var.s3_payments_bucket_name
}

data "aws_iam_policy_document" "graphql_abacus_put_only_bucket_policy" {
  statement {
    effect = "Allow"

    actions = [
      "s3:PutObject",
    ]

    resources = [
      "${data.aws_s3_bucket.graphql_abacus_payments_bucket.arn}/*",
    ]
  }
}

resource "aws_iam_policy" "graphql_abacus_put_only_bucket_policy" {
  name        = "S3-${var.environment}-abacus-buckets-WO"
  description = "Write access to qa abacus bucket(s)"
  policy      = data.aws_iam_policy_document.graphql_abacus_put_only_bucket_policy.json
}

data "aws_iam_policy" "abacus_adjustments_usage_policy" {
  name = var.s3_abacus_adjustments_usage_policy
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type        = "AWS"
      identifiers = [module.graphql_abacus_fargate_environment.fargate_task_iam_role_arn]
    }
  }
}

resource "aws_iam_role" "graphql_abacus_browser_upload_role" {
  name                 = "${var.environment}-graphql-abacus-browser-upload-role"
  max_session_duration = var.bucket_upload_token_duration
  assume_role_policy   = data.aws_iam_policy_document.assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "graphql_abacus_payments_browser_upload_policy_attachment" {
  role       = aws_iam_role.graphql_abacus_browser_upload_role.id
  policy_arn = aws_iam_policy.graphql_abacus_put_only_bucket_policy.arn
}

resource "aws_iam_role_policy_attachment" "graphql_abacus_adjustments_browser_upload_policy_attachment" {
  role       = aws_iam_role.graphql_abacus_browser_upload_role.id
  policy_arn = data.aws_iam_policy.abacus_adjustments_usage_policy.arn
}

data "aws_iam_policy_document" "graphql_abacus_browser_upload_assume_role_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    resources = [
      aws_iam_role.graphql_abacus_browser_upload_role.arn
    ]
  }
}

resource "aws_iam_policy" "graphql_abacus_browser_upload_assume_role_policy" {
  name        = "${var.environment}-graphql-abacus-browser-upload-assume-role-policy"
  description = "Assume browser upload role used by the graphql-abacus fargate role."
  policy      = data.aws_iam_policy_document.graphql_abacus_browser_upload_assume_role_policy_document.json
}

resource "aws_iam_role_policy_attachment" "graphql_abacus_browser_upload_policy_attachment_to_fargate" {
  role       = module.graphql_abacus_fargate_environment.fargate_task_iam_role_name
  policy_arn = aws_iam_policy.graphql_abacus_browser_upload_assume_role_policy.arn
}

data "aws_iam_policy" "existing_policies_to_attach" {
  for_each = toset(var.existing_policies_to_attach)
  name     = each.value
}

# Bedrock permissions for experimental Abacus chatbot (ACC-9536)
# Allows inference-only access to Claude models in QA
# Note: Cross-Region inference profile routes across US regions (aws determines best region due to availability)
data "aws_iam_policy_document" "graphql_abacus_bedrock_policy_document" {
  statement {
    sid    = "AllowBedrockModelInvoke"
    effect = "Allow"

    actions = [
      "bedrock:InvokeModel",
      "bedrock:InvokeModelWithResponseStream",
    ]

    resources = [
      "arn:aws:bedrock:us-*::foundation-model/anthropic.claude-opus-4-6-*",
      "arn:aws:bedrock:us-*:${data.aws_caller_identity.current.account_id}:inference-profile/us.anthropic.claude-opus-4-6-*",
      "arn:aws:bedrock:us-*::foundation-model/anthropic.claude-sonnet-4-6",
      "arn:aws:bedrock:us-*:${data.aws_caller_identity.current.account_id}:inference-profile/us.anthropic.claude-sonnet-4-6",
      "arn:aws:bedrock:us-*::foundation-model/anthropic.claude-haiku-4-5-*",
      "arn:aws:bedrock:us-*:${data.aws_caller_identity.current.account_id}:inference-profile/us.anthropic.claude-haiku-4-5-*"
    ]
  }
}

resource "aws_iam_policy" "graphql_abacus_bedrock_policy" {
  name        = "${var.environment}-graphql-abacus-bedrock-policy"
  description = "Allow graphql-abacus to invoke Bedrock models for experimental Abacus chatbot"
  policy      = data.aws_iam_policy_document.graphql_abacus_bedrock_policy_document.json
}

resource "aws_iam_role_policy_attachment" "graphql_abacus_bedrock_policy_attachment" {
  role       = module.graphql_abacus_fargate_environment.fargate_task_iam_role_name
  policy_arn = aws_iam_policy.graphql_abacus_bedrock_policy.arn
}