module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/graphql-knowledge-search/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_iam_policy" "elastic_search_rw_policy" {
  name = "Elasticsearch-qa-music-graph-os-RW-policy"
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io."
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

module "graphql_knowledge_search_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = var.service_name
  application_family = var.application_family
}

module "graphql_knowledge_search_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.7.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.region
  application_family                       = var.application_family
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 1024
  task_memory                              = var.task_memory
  datadog_task_memory                      = var.datadog_memory
  maximum_capacity                         = 4
  minimum_capacity                         = 2
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  http_listener_enabled                    = false

  iam_managed_policy_attachments = [
    data.aws_iam_policy.elastic_search_rw_policy.arn,
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      NODE_OPTIONS = "--max-old-space-size=${var.task_memory - var.datadog_memory}"
    },
    {
      Environment = var.environment
    },
    {
      NODE_ENV = var.environment
    },
    {
      APOLLO_INTROSPECTION = "true"
    },
    {
      APOLLO_PLAYGROUND = "true"
    },
    {
      DD_LOGS_INJECTION = true
    },
    {
      CACHE_REDIS_HOST = "rediss://${module.elasticache.redis_primary_endpoint_address}:6379"
    },
    {
      CACHE_USE_REDIS = true
    }
  ]

  secrets = [
    {
      SENTRY_DSN = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
    # Send both ES and OS creds and let service switch between those using FFlag.
    {
      OPENSEARCH_URL = "${var.environment}/${var.service_name}/OPENSEARCH_URL"
    },
    {
      OPENSEARCH_USERNAME = "${var.environment}/${var.service_name}/OPENSEARCH_USERNAME"
    },
    {
      OPENSEARCH_PASSWORD = "${var.environment}/${var.service_name}/OPENSEARCH_PASSWORD"
    },
    {
      ELASTICSEARCH_URL = "${var.environment}/${var.service_name}/ELASTICSEARCH_URL"
    },
    {
      ELASTICSEARCH_USERNAME = "${var.environment}/${var.service_name}/ELASTICSEARCH_USERNAME"
    },
    {
      ELASTICSEARCH_PASSWORD = "${var.environment}/${var.service_name}/ELASTICSEARCH_PASSWORD"
    },

    {
      SPLIT_API_KEY = "${var.environment}/${var.service_name}/SPLIT_API_KEY"
    },
    {
      SPOTIFY_CLIENT_ID = "${var.environment}/${var.service_name}/SPOTIFY_CLIENT_ID"
    },
    {
      SPOTIFY_CLIENT_SECRET = "${var.environment}/${var.service_name}/SPOTIFY_CLIENT_SECRET"
    }
  ]
}

module "graphql_knowledge_search_service_dashboard" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.6"
  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  notification_endpoints            = "@slack-monitoring @slack-graphql"
  datadog_service_type              = "${var.service_name}-graphql"
  datadog_service_name              = "graphql.execute"
  service_4xx_monitor_enabled       = true
  service_5xx_monitor_enabled       = true
  application_family                = var.application_family
  escalation_notification_endpoints = "@slack-insights-go-backend-alerts"
}

module "elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.1.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                      = var.environment
  service_name                     = var.service_name
  application_family               = var.application_family
  cache_engine                     = "redis"
  redis_engine_version             = "6.x"
  cache_parameter_group_name       = "default.redis6.x"
  cache_subnet_group_name          = "${var.environment}-elasticache-subnet-group"
  cache_node_type                  = "cache.t4g.small"
  route53_zone_id                  = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                           = module.vpc_info.vpc_id
  cache_transit_encryption_enabled = true
  cache_at_rest_encryption_enabled = true
  additional_cidr_blocks_enabled   = true
  additional_cidr_blocks = [
    "10.30.0.0/22",
    "192.168.32.0/24",
    "192.168.33.0/24",
    "192.168.40.0/22",
    "10.40.0.0/22",
  ]
}

module "graphql_knowledge_search_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  # temporary switch to KDH app family so we can edit the secrets with real values.
  application_family = var.kdh_application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}