data "aws_iam_role" "pipeline_agent_role" {
  name = "prod-jenkins-aws-pipeline-agent"
}

data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  version = "2012-10-17"
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        data.aws_iam_role.pipeline_agent_role.arn,
      ]
    }
  }
}

module "cross_app_data_tests_secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.4.0"

  secrets = [
    "${var.environment}/datadog/DD_APP_KEY",
    "${var.environment}/datadog/DD_API_KEY",
  ]
  action_types = ["read"]
}

resource "aws_iam_policy" "cross_app_data_tests_secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-policy"
  policy = module.cross_app_data_tests_secrets_manager_policy.policy.json
}

resource "aws_iam_role" "cross_app_data_tests_role" {
  name = "${var.environment}-${var.service_name}-role"

  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "cross_app_data_tests_role_policy_attachment" {
  role       = aws_iam_role.cross_app_data_tests_role.name
  policy_arn = aws_iam_policy.cross_app_data_tests_secrets_manager_policy.arn
}