module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.application_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/kafka-infra/db_deploy/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.0.2"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

resource "aws_ecr_repository" "kafka_connect_db_deploy" {
  name = local.service_name
  image_scanning_configuration {
    scan_on_push = true
  }
  encryption_configuration {
    encryption_type = "KMS"
  }
}

module "kafka_db_deploy_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = local.secret_service_name
  secret_name        = each.value
  application_family = var.application_family
}

data "aws_iam_policy_document" "kafka_db_deploy_secretsmanager_policy" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]
    resources = [
      "arn:aws:secretsmanager:${var.aws_region}:${data.aws_caller_identity.current.account_id}:secret:${var.environment}/kafka-db-deploy/",
      "arn:aws:secretsmanager:${var.aws_region}:${data.aws_caller_identity.current.account_id}:secret:${var.environment}/kafka-db-deploy/*",
    ]
  }
}

module "kconnect_db_deploy_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                       = var.environment
  service_name                      = local.service_name
  non_ecr_image                     = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/${local.service_name}:latest"
  application_family                = var.application_family
  additional_tags                   = var.additional_tags
  aws_region                        = var.aws_region
  service_platform_version          = "1.4.0"
  desired_task_count                = 1
  minimum_capacity                  = 1
  maximum_capacity                  = 1
  task_cpu                          = 1024
  task_memory                       = 3072
  container_port                    = 8083
  health_check_grace_period_seconds = 180
  container_start_period_seconds    = 180
  #  See SYS-20260 the WAF rule Log4JRCE_BODY blocks db-deploys
  blocking_waf_enabled                  = true
  custom_waf_arn                        = module.kconnect_db_deploy_waf.waf_blocking_arn_output
  health_check_path                     = "/connectors"
  web_service_health_check_command      = "[[ /etc/confluent/docker/healthcheck.sh ]] || exit 1"
  propagate_tags                        = true

  force_new_deployment                  = true

  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  fargate_service_subnets       = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets         = module.vpc_info.default_private_subnet_ids

  iam_managed_policy_attachments = [
    aws_iam_policy.secretsmanager_read_only_policy.arn
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      SERVICE_NAME = local.service_name
    },
    {
      CONNECT_GROUP_ID = local.ecs_cluster_name
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = var.connect_bootstrap_servers
    },
  ]
}

module "db_deploy_status_dynamodb_table" {
  source = "git@github.com:theorchard/terraform-dynamodb.git//?ref=3.3.1"

  env                = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  use_on_demand      = false
  table_name         = "kafka_db_deploy_status"
  hash_key           = "changeset_id"

  attribute = [
    {
      name = "changeset_id"
      type = "S"
    },
  ]
}

# This rule will allow kafka-connect tasks to communicate with each other in distributed mode
resource "aws_security_group_rule" "allow_intra_cluster_communication_db" {
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.kconnect_db_deploy_fargate_environment.fargate_security_group_id
  self              = true
  type              = "ingress"
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/kafka_connector?ref=6.15.2"

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  environment_type   = "fargate"
  service_name       = local.service_name

  teams               = ["kdh"]
  notification_endpoints            = "@slack-kafka-data-highway-alerts"
  escalation_notification_endpoints = "@slack-kafka-data-highway-alerts"
  healthy_tasks_monitor_enabled     = true
  service_cpu_monitor_enabled       = true
  error_monitor_enabled             = true
  healthy_tasks_evaluation_window   = "last_1h"
  service_cpu_time_window           = "last_1h"
  # Alert on the number of times the metric shows unhealthy tasks within the last hour
  healthy_tasks_critical_number = 5
}

module "kconnect_db_deploy_waf" {
  source            = "git@github.com:theorchard/terraform-aws-waf.git//?ref=1.5.0"
  environment       = var.environment
  service_name      = local.service_name
  aws_region        = var.aws_region
  count_waf_enabled = false
  excluded_rules = [
    "Log4JRCE_BODY",
    "SizeRestrictions_BODY",
  ]
}

resource "aws_iam_policy" "secretsmanager_read_only_policy" {
  name        = "SecretsManager-qa-kafka-db-deploy-policy"
  description = "SecretsManager-qa-kafka-db-deploy-policy"
  policy      = data.aws_iam_policy_document.kafka_db_deploy_secretsmanager_policy.json
}