data "aws_secretsmanager_secret" "datadog_api" {
  name = "${var.environment}/datadog/DD_API_KEY"
}

data "aws_secretsmanager_secret_version" "datadog_api" {
  secret_id = data.aws_secretsmanager_secret.datadog_api.id
}

data "aws_secretsmanager_secret" "datadog_app_key" {
  name = "${var.environment}/datadog/DD_APP_KEY"
}

data "aws_secretsmanager_secret_version" "datadog_app_key" {
  secret_id = data.aws_secretsmanager_secret.datadog_app_key.id
}

# Datadog provider
provider "datadog" {
  api_key = data.aws_secretsmanager_secret_version.datadog_api.secret_string
  app_key = data.aws_secretsmanager_secret_version.datadog_app_key.secret_string
}

resource "datadog_monitor" "kafka_connector_dlq_monitor" {
  count   = var.datadog_monitor_enabled ? 1 : 0
  name    = "${local.service_name}-dlq-monitor"
  type    = "metric alert"
  message = "[${var.environment}] JDBC Sink NR Connector sent a message into DLQ topic. Notify: @slack-kafka-data-highway-alerts"

  query = "max(last_1m):avg:aws.kafka.messages_in_per_sec{cluster_name:${var.msk_cluster_name},topic:${lower(var.dlq_topic_name)}} > ${var.datadog_monitor_threshold}"

  monitor_thresholds {
    critical = var.datadog_monitor_threshold
  }

  notify_no_data      = false
  notify_audit        = false
  renotify_interval   = 60
  timeout_h           = 0
  require_full_window = false

  tags = flatten(concat([
    "environment:${var.environment}",
    "service_name:${local.service_name}",
    ],
    [for tag_name, tag_value in var.additional_tags : "${tag_name}:${tag_value}"]
  ))
}