module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = local.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/kafka-infra/neo4j_cdc_sink/chartmetric-charts/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

module "kafka_neo_sink_cmc_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                           = var.environment
  application_family                    = var.application_family
  additional_tags                       = var.additional_tags
  service_name                          = local.service_name
  non_ecr_image                         = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/${local.ecr_image_name}:latest"
  aws_region                            = var.aws_region
  service_platform_version              = "1.4.0"
  desired_task_count                    = 1
  minimum_capacity                      = 1
  maximum_capacity                      = 2
  task_cpu                              = 1024
  task_memory                           = 3072
  container_port                        = 8083
  health_check_grace_period_seconds     = 120
  container_start_period_seconds        = 120
  blocking_waf_enabled                  = true
  health_check_path                     = "/connectors/${local.service_name}"
  web_service_health_check_command      = "[[ $(curl -s http://localhost:8083/connectors/${local.service_name}/status | jq -r '.tasks[].state' | sort | uniq) == 'RUNNING' ]] || exit 1"
  fargate_spot_capacity_provider_weight = 100
  task_placement_failure_alert_enabled  = true
  route53_zone_id                       = data.aws_route53_zone.route53_zone.zone_id
  propagate_tags                        = true

  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  datadog_custom_image = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/orchard-datadog-agent-jmx:latest"
  # datadog agent crashes due to OutOfMemoryError with JMX. So increase it from 256
  datadog_task_memory = 512
  datadog_agent_environment_variables = [
    {
      JMX_PORT = "9095"
    },
    {
      DD_ENV = var.environment
    },
    {
      SERVICE_NAME = local.service_name
    },
    {
      CONNECTOR_TYPE = "default_sink"
    },
  ]
  environment_variables = [
    {
      Environment = var.environment
    },
    {
      CONNECT_GROUP_UNIQUE_IDENTIFIER = "${var.environment}-${local.service_name}"
    },
    {
      CONNECTOR_NAME = local.service_name
    },
    {
      SERVICE_NAME = local.service_name
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = var.connect_bootstrap_servers
    },
    {
      NEO4J_SERVER_URI = "neo4j+s://${var.environment}-neo4j-cluster.theorchard.io:7687"
    },
    {
      NEO4J_KEY_CONVERTER = "org.apache.kafka.connect.storage.StringConverter"
    },
    {
      NEO4J_VALUE_CONVERTER = "org.apache.kafka.connect.json.JsonConverter"
    },
    {
      MAX_TASKS = "2"
    },
    {
      NEO4J_KEY_CONVERTER_SCHEMAS_ENABLE = "false"
    },
    {
      NEO4J_VALUE_CONVERTER_SCHEMAS_ENABLE = "false"
    },
    {
      NEO4J_BATCH_SIZE = "2500"
    },
    {
      NEO4J_BATCH_EXEC_TIMEOUT = "30s"
    },

    {
      TOPIC_MAPPING_GLOBALSOUNDRECORDING_RELATIONS = "etl.chartmetric.charts.globalsoundrecording.relations|${local.globalsoundrecording_relations}"
    },
    {
      TOPIC_MAPPING_SOUNDRECORDING_NOISRC = "etl.chartmetric.charts.soundrecording.noisrc.nodes|${local.soundrecording_noisrc}"
    },
    {
      TOPIC_MAPPING_AMAZON_TRACKANDPARTICIPANT = "etl.chartmetric.charts.amazon.trackandparticipant.relations|${local.amazon_trackandparticipant}"
    },
    {
      TOPIC_MAPPING_APPLEMUSIC_TRACKANDPARTICIPANT = "etl.chartmetric.charts.applemusic.trackandparticipant.relations|${local.applemusic_trackandparticipant}"
    },
    {
      TOPIC_MAPPING_DEEZER_TRACKANDPARTICIPANT = "etl.chartmetric.charts.deezer.trackandparticipant.relations|${local.deezer_trackandparticipant}"
    },
    {
      TOPIC_MAPPING_ITUNES_TRACKANDPARTICIPANT = "etl.chartmetric.charts.itunes.trackandparticipant.relations|${local.itunes_trackandparticipant}"
    },
    {
      TOPIC_MAPPING_LINEMUSIC_TRACKANDPARTICIPANT = "etl.chartmetric.charts.linemusic.trackandparticipant.relations|${local.linemusic_trackandparticipant}"
    },
    {
      TOPIC_MAPPING_RECOCHOKU_TRACKANDPARTICIPANT = "etl.chartmetric.charts.recochoku.trackandparticipant.relations|${local.recochoku_trackandparticipant}"
    },
    {
      TOPIC_MAPPING_SHAZAM_TRACKANDPARTICIPANT = "etl.chartmetric.charts.shazam.trackandparticipant.relations|${local.shazam_trackandparticipant}"
    },
    {
      TOPIC_MAPPING_SOUNDCLOUD_TRACKANDPARTICIPANT = "etl.chartmetric.charts.soundcloud.trackandparticipant.relations|${local.soundcloud_trackandparticipant}"
    },
    {
      TOPIC_MAPPING_SPOTIFY_TRACKANDPARTICIPANT = "etl.chartmetric.charts.spotify.trackandparticipant.relations|${local.spotify_trackandparticipant}"
    },
    {
      TOPIC_MAPPING_TIKTOK_TRACKANDPARTICIPANT = "etl.chartmetric.charts.tiktok.trackandparticipant.relations|${local.tiktok_trackandparticipant}"
    },
    {
      TOPIC_MAPPING_YOUTUBE_TRACKANDPARTICIPANT = "etl.chartmetric.charts.youtube.trackandparticipant.relations|${local.youtube_trackandparticipant}"
    },
    {
      TOPIC_MAPPING_AMAZON_PRODUCTANDLABEL = "etl.chartmetric.charts.amazon.productandlabel.relations|${local.amazon_productandlabel}"
    },
    {
      TOPIC_MAPPING_APPLEMUSIC_PRODUCTANDLABEL = "etl.chartmetric.charts.applemusic.productandlabel.relations|${local.applemusic_productandlabel}"
    },
    {
      TOPIC_MAPPING_DEEZER_PRODUCTANDLABEL = "etl.chartmetric.charts.deezer.productandlabel.relations|${local.deezer_productandlabel}"
    },
    {
      TOPIC_MAPPING_ITUNES_PRODUCTANDLABEL = "etl.chartmetric.charts.itunes.productandlabel.relations|${local.itunes_productandlabel}"
    },
    {
      TOPIC_MAPPING_SHAZAM_PRODUCTANDLABEL = "etl.chartmetric.charts.shazam.productandlabel.relations|${local.shazam_productandlabel}"
    },
    {
      TOPIC_MAPPING_SPOTIFY_PRODUCTANDLABEL = "etl.chartmetric.charts.spotify.productandlabel.relations|${local.spotify_productandlabel}"
    },

    {
      AWS_SECRETS_MANAGER = "true"
    },
    {
      AWS_REGION = var.aws_region
    },
    {
      DLQ_TOPIC_NAME = "dlq.chartmetric.charts.neo4jsink.status"
    },
    {
      DEBUG_MODE = "true"
    },
  ]
}

resource "aws_security_group_rule" "allow_intra_cluster_communication_cmc" {
  description       = "This rule will allow kafka-connect tasks to communicate with each other in distributed mode."
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.kafka_neo_sink_cmc_fargate_environment.fargate_security_group_id
  self              = true
  type              = "ingress"
}


module "service_credentials_secret" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  environment                    = var.environment
  application_family             = var.application_family
  additional_tags                = var.additional_tags
  service_name                   = local.service_name
  secret_name                    = "NEO4J_CREDENTIALS"
  secret_recovery_window_in_days = 7
}

module "fargate_service_dashboard_cmc" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/kafka_connector?ref=6.13.4"

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  service_name       = local.service_name
  connector_type     = "default_sink"

  environment_type = "fargate"

  notification_endpoints            = "@slack-kafka-data-highway-alerts @slack-data-alerts-qa"
  escalation_notification_endpoints = "@slack-data-alarm-qa"
  healthy_tasks_monitor_enabled     = false
  monitor_kafka_topics = [
    "etl.chartmetric.charts.globalsoundrecording.relations",
    "etl.chartmetric.charts.soundrecording.noisrc.nodes",
    "etl.chartmetric.charts.amazon.trackandparticipant.relations",
    "etl.chartmetric.charts.applemusic.trackandparticipant.relations",
    "etl.chartmetric.charts.deezer.trackandparticipant.relations",
    "etl.chartmetric.charts.linemusic.trackandparticipant.relations",
    "etl.chartmetric.charts.recochoku.trackandparticipant.relations",
    "etl.chartmetric.charts.shazam.trackandparticipant.relations",
    "etl.chartmetric.charts.soundcloud.trackandparticipant.relations",
    "etl.chartmetric.charts.spotify.trackandparticipant.relations",
    "etl.chartmetric.charts.tiktok.trackandparticipant.relations",
    "etl.chartmetric.charts.youtube.trackandparticipant.relations",
    "etl.chartmetric.charts.itunes.trackandparticipant.relations",
    "etl.chartmetric.charts.amazon.productandlabel.relations",
    "etl.chartmetric.charts.applemusic.productandlabel.relations",
    "etl.chartmetric.charts.deezer.productandlabel.relations",
    "etl.chartmetric.charts.shazam.productandlabel.relations",
    "etl.chartmetric.charts.spotify.productandlabel.relations",
    "etl.chartmetric.charts.itunes.productandlabel.relations",
  ]

  service_cpu_monitor_enabled = true
  error_monitor_enabled       = true
}