module "kafka_neo_sink_fingerprinting_backfill_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.2"

  providers = {
    aws.dns = aws.networking
  }

  environment                       = var.environment
  application_family                = var.application_family
  additional_tags                   = var.additional_tags
  service_name                      = var.service_name
  non_ecr_image                     = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/${var.ecr_image_name}:latest"
  aws_region                        = var.aws_region
  service_platform_version          = "1.4.0"
  desired_task_count                = 0
  minimum_capacity                  = 0
  maximum_capacity                  = 0
  task_cpu                          = 1024
  task_memory                       = 4096
  container_port                    = 8083
  health_check_grace_period_seconds = 300
  container_start_period_seconds    = 300
  blocking_waf_enabled              = true
  health_check_path                 = "/connectors/${var.service_name}"
  web_service_health_check_command  = "[[ $(curl -s http://localhost:8083/connectors/${var.service_name}/status | jq -r '.tasks[].state' | sort | uniq) == 'RUNNING' ]] || exit 1"
  # QA-only: Use SPOT instances
  fargate_spot_capacity_provider_weight = 100
  task_placement_failure_alert_enabled  = true
  propagate_tags                        = true
  vpc_id                                = module.vpc_info.vpc_id
  https_listener_certificate_id         = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  fargate_service_subnets               = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                 = module.vpc_info.default_private_subnet_ids

  datadog_custom_image = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/orchard-datadog-agent-jmx:latest"
  # datadog agent crashes due to OutOfMemoryError with JMX. So increase it from 256
  datadog_task_memory = 512
  datadog_agent_environment_variables = [
    {
      JMX_PORT = "9095"
    },
    {
      DD_ENV = var.environment
    },
    {
      SERVICE_NAME = var.service_name
    },
    {
      CONNECTOR_TYPE = "default_sink"
    },
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      CONNECT_GROUP_UNIQUE_IDENTIFIER = "${var.environment}-${var.service_name}"
    },
    {
      CONNECTOR_NAME = var.service_name
    },
    {
      SERVICE_NAME = var.service_name
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = var.connect_bootstrap_servers
    },
    {
      NEO4J_SERVER_URI = var.neo4j_server_url
    },
    {
      NEO4J_DATABASE_NAME = "neo4j"  # Default is graph.db
    },
    {
      NEO4J_KEY_CONVERTER = "org.apache.kafka.connect.json.JsonConverter"
    },
    {
      NEO4J_VALUE_CONVERTER = "org.apache.kafka.connect.json.JsonConverter"
    },
    {
      MAX_TASKS = "5"
    },
    {
      NEO4J_KEY_CONVERTER_SCHEMAS_ENABLE = "false"
    },
    {
      NEO4J_VALUE_CONVERTER_SCHEMAS_ENABLE = "false"
    },
    {
      NEO4J_BATCH_SIZE = "300"
    },
    {
      NEO4J_BATCH_EXEC_TIMEOUT = "60s"
    },
    # All backfill topics.
    {
      TOPIC_MAPPING_ORCHARD_ASSET = "event.snowflake.fp.backfill.orchardAsset|${local.orchard_asset_query}"
    },
    {
      TOPIC_MAPPING_ACRID = "event.snowflake.fp.backfill.acrid|${local.acrid_query}"
    },
    {
      TOPIC_MAPPING_FINGERPRINTED_AS = "event.snowflake.fp.backfill.fingerprintedAs|${local.fingerprinted_as_query}"
    },

    {
      DLQ_TOPIC_NAME = "dlq.event.neo.cdc.sink.fp.backfill"
    },
    {
      AWS_SECRETS_MANAGER = "true"
    },
    {
      AWS_REGION = var.aws_region
    },
    {
      DEBUG_MODE = "false"
    },
  ]
}

resource "aws_security_group_rule" "allow_intra_cluster_communication_fingerprinting_backfill" {
  description       = "This rule will allow kafka-connect tasks to communicate with each other in distributed mode."
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.kafka_neo_sink_fingerprinting_backfill_fargate_environment.fargate_security_group_id
  self              = true
  type              = "ingress"
}

module "service_credentials_secret_fingerprinting_backfill" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  environment                    = var.environment
  application_family             = var.application_family
  additional_tags                = var.additional_tags
  service_name                   = var.service_name
  secret_name                    = "NEO4J_CREDENTIALS"
  secret_recovery_window_in_days = 7
}

module "fargate_service_dashboard_fingerprinting_backfill" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/kafka_connector?ref=6.15.2"

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  service_name       = var.service_name

  connector_type   = "default_sink"
  environment_type = "fargate"

  notification_endpoints            = "@slack-kafka-data-highway-alerts"
  escalation_notification_endpoints = "@slack-kafka-data-highway-alerts"
  monitor_kafka_topics = [
    "event.snowflake.fp.backfill.orchardAsset",
    "event.snowflake.fp.backfill.acrid",
    "event.snowflake.fp.backfill.fingerprintedAs",
    "dlq.event.neo.cdc.sink.fp.backfill"
  ]
  monitor_kafka_topics_cluster_name = "qa-managed-kafka-cdc-destination"

  healthy_tasks_monitor_enabled   = false
  service_cpu_monitor_enabled     = false
  error_monitor_enabled           = false
  healthy_tasks_evaluation_window = "last_1h"
  service_cpu_time_window         = "last_1h"
}