# OS creds
module "connector_secrets_track" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  service_name       = local.track_service_name
  secret_name        = "OPENSEARCH_CREDENTIALS"
}

# track OS Sink Fargate service
module "os_sink_fargate_environment_track" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.3.0"

  providers = {
    aws.dns = aws.networking
  }

  environment                           = var.environment
  application_family                    = var.application_family
  additional_tags                       = var.additional_tags
  service_name                          = local.track_service_name
  non_ecr_image                         = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/${local.ecr_repo_name}:latest"
  aws_region                            = var.aws_region
  service_platform_version              = "1.4.0"
  desired_task_count                    = 1
  minimum_capacity                      = 1
  maximum_capacity                      = 1
  task_cpu                              = 2048
  task_memory                           = 4096
  autoscaling_cpu_policy_enabled        = false
  autoscaling_memory_policy_enabled     = false
  container_port                        = 8083
  health_check_grace_period_seconds     = 300
  blocking_waf_enabled                  = true
  health_check_path                     = "/connectors/${var.environment}-${local.track_service_name}/status"
  web_service_health_check_command      = "[[ $(curl -s http://localhost:8083/connectors/${var.environment}-${local.track_service_name}/status | jq -r '.tasks[].state' | sort | uniq) == 'RUNNING' ]] || exit 1"
  vpc_id                                = module.vpc_info.vpc_id
  fargate_service_subnets               = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                 = module.vpc_info.default_private_subnet_ids
  propagate_tags                        = true
  fargate_spot_capacity_provider_weight = 100
  task_placement_failure_alert_enabled  = true

  iam_managed_policy_attachments = [
    data.aws_iam_policy.opensearch_default_rw_policy.arn
  ]
  datadog_custom_image = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/orchard-datadog-agent-jmx:latest"
  # datadog agent crashes due to OutOfMemoryError with JMX. So increase it from 256
  datadog_task_memory = 512
  datadog_agent_environment_variables = [
    {
      JMX_PORT = "9095"
    },
    {
      DD_ENV = var.environment
    },
    {
      SERVICE_NAME = local.track_service_name
    },
    {
      CONNECTOR_TYPE = "default_sink"
    },
  ]
  environment_variables = [
    {
      Environment = var.environment
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = var.connect_bootstrap_servers
    },
    {
      CONNECTOR_NAME = "${var.environment}-${local.track_service_name}"
    },
    {
      CONNECT_GROUP_UNIQUE_IDENTIFIER = "${var.environment}-${local.track_service_name}"
    },
    {
      MAX_TASKS = "3"
    },
    {
      OPENSEARCH_HOST = "https://${data.aws_opensearch_domain.content_search_domain.endpoint}"
    },
    {
      OPENSEARCH_DOC_TYPE = "_doc"
    },
    {
      OPENSEARCH_KEY_IGNORE = "false"
    },
    {
      OPENSEARCH_SCHEMA_IGNORE = "true"
    },
    {
      KAFKA_TOPICS = join(",", [
        "event.backup.prod.etl.tracks",
      ])
    },
    {
      SECRETS_MANAGER_OPENSEARCH_SECRET_NAME = "OPENSEARCH_CREDENTIALS"
    },
    {
      SERVICE_NAME = local.track_service_name
    },
    {
      TRANSFORMS_RENAMETOPIC_REPLACEMENT = "track_write"
    },
    # Try smaller batches and flush more frequently ie: 60 sec instead of 100 sec.
    {
      BATCH_SIZE = "1000"
    },
    {
      MAX_INFLIGHT_REQUESTS = "6"
    },
    {
      MAX_BUFFERED_RECORDS = "6000"
    },
    {
      FLUSH_TIMEOUT_MS = "60000"
    },
    {
      READ_TIMEOUT_MS = "60000"
    },

    {
      TRANSFORMS_RENAMETOPIC_REGEX = ".*"
    },
    {
      TRANSFORMS_RENAMETOPIC_TYPE = "org.apache.kafka.connect.transforms.RegexRouter"
    },
    {
      TRANSFORMS = "renameTopic"
    },
    {
      WRITE_METHOD = "upsert"
    },
    {
      DLQ_TOPIC_NAME = local.track_dlq_topic_name
    },
    {
      DLQ_HEADERS_ENABLE = "true"
    },
    {
      DEBUG_MODE = "true"
    },
    {
      CONNECT_LOG4J_ROOT_LOGLEVEL = "INFO"
    }
  ]
}

# This rule will allow kafka-connect tasks to communicate with each other in distributed mode
resource "aws_security_group_rule" "allow_intra_cluster_communication_track" {
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.os_sink_fargate_environment_track.fargate_security_group_id
  self              = true
  type              = "ingress"
}

# Datadog dashboard.
module "fargate_service_dashboard_track" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/kafka_connector?ref=6.15.2"

  environment        = var.environment
  environment_type   = "fargate"
  service_name       = local.track_service_name
  application_family = var.application_family
  teams              = var.dd_teams
  additional_tags    = var.additional_tags
  connector_type     = "default_sink"

  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints
  monitor_kafka_topics = [
    "event.backup.prod.etl.tracks",
  ]

  healthy_tasks_monitor_enabled        = true
  service_cpu_monitor_enabled          = true
  error_monitor_enabled                = true
  dlq_topic_name                       = local.track_dlq_topic_name
  error_monitor_critical_number_errors = 10
}