module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/kafka-infra/salesforce_sink/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.0.2"

  environment = var.environment
}

data "aws_acm_certificate" "theorchard_io" {
  domain   = "*.theorchard.io"
  statuses = ["ISSUED"]
}

data "aws_route53_zone" "route53_zone" {
  name = "theorchard.io"
}

resource "aws_ecr_repository" "kafka_connect_sforce_sink_repository" {
  name = "${var.service_name}-sforce-sink"

  image_scanning_configuration {
    scan_on_push = true
  }

  encryption_configuration {
    encryption_type = "KMS"
  }
}

module "kafka_sforce_sink_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.5.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                           = var.environment
  application_family                    = var.application_family
  additional_tags                       = var.additional_tags
  service_name                          = "${var.service_name}-sforce-sink"
  non_ecr_image                         = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/kafka-connect-sforce-sink:latest"
  aws_region                            = var.aws_region
  service_platform_version              = "1.4.0"
  desired_task_count                    = 1
  minimum_capacity                      = 1
  maximum_capacity                      = 2
  task_cpu                              = 1024
  task_memory                           = 3072
  container_port                        = 8083
  health_check_grace_period_seconds     = 180
  container_start_period_seconds        = 180
  blocking_waf_enabled                  = true
  health_check_path                     = "/connectors/${var.connector_name}"
  web_service_health_check_command      = "[[ $(curl -s http://localhost:8083/connectors/${var.connector_name}/status | jq -r '.tasks[].state' | sort | uniq) == 'RUNNING' ]] || exit 1"
  route53_zone_id                       = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                                = module.vpc_info.vpc_id
  https_listener_certificate_id         = split("/", data.aws_acm_certificate.theorchard_io.arn)[1]
  propagate_tags                        = true
  fargate_spot_capacity_provider_weight = 100
  task_placement_failure_alert_enabled  = true

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  datadog_custom_image = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/orchard-datadog-agent-jmx:latest"
  # datadog agent crashes due to OutOfMemoryError with JMX. So increase it from 256
  datadog_task_memory = 512
  datadog_agent_environment_variables = [
    {
      JMX_PORT = "9095"
    },
    {
      DD_ENV = var.environment
    },
    {
      SERVICE_NAME = "${var.service_name}-sforce-sink"
    },
    {
      CONNECTOR_TYPE = "default_sink"
    },
  ]
  environment_variables = [
    {
      Environment = var.environment
    },
    {
      SERVICE_NAME = "${var.service_name}-sforce-sink"
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = var.connect_bootstrap_servers
    },
    {
      KAFKA_TOPICS = var.kafka_topics
    },
    {
      START_READING_RECORDS_FROM = var.start_reading_records_from
    },
    {
      CONNECTOR_NAME = var.connector_name
    },
    {
      CONNECT_KEY_CONVERTER = "org.apache.kafka.connect.storage.StringConverter"
    },
    {
      CONNECT_VALUE_CONVERTER = "org.apache.kafka.connect.storage.StringConverter"
    },
    {
      SECRETS_MANAGER_SF_CREDS = "salesforce_credentials"
    },
    {
      SOBJECT_NAME = "Lead"
    },
    {
      SOBJECT_ID_NAME = "Orchard_Lead_Id__c"
    },
    {
      SOBJECT_OPERATION = "upsertSObject"
    },
    {
      SF_INSTANCE = var.salesforce_login_url
    },
    {
      DLQ_TOPIC_NAME = var.dlq_topic_name
    },
    {
      DLQ_HEADERS_ENABLE = var.dlq_headers_enable
    },
    {
      CONNECT_LOG4J_ROOT_LOGLEVEL = var.kafka_connect_root_log_level
    },
    {
      DEBUG_MODE = "false"
    },
    {
      CONNECT_LOG4J_ROOT_LOGLEVEL = "ERROR"
    }
  ]
}

# This rule will allow kafka-connect tasks to communicate with each other in distributed mode
resource "aws_security_group_rule" "allow_intra_cluster_communication" {
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.kafka_sforce_sink_fargate_environment.fargate_security_group_id
  self              = true
  type              = "ingress"
}

# Datadog monitor module
module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/kafka_connector?ref=6.15.2"

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  environment_type   = "fargate"
  service_name       = "${var.service_name}-sforce-sink"
  connector_type     = "default_sink"

  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
  monitor_kafka_topics              = ["event.gdaSignup"]
  monitor_kafka_topics_cluster_name = "qa-managed-kafka-artist-diy"

  healthy_tasks_monitor_enabled = true
  service_cpu_monitor_enabled   = true
  error_monitor_enabled         = true
  healthy_tasks_evaluation_window = "last_1h"
  service_cpu_time_window         = "last_1h"
  # Alert on the number of times the metric shows unhealthy tasks within the last hour
  healthy_tasks_critical_number        = 5
}

module "salesforce_credentials" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  environment                    = var.environment
  application_family             = var.application_family
  additional_tags                = var.additional_tags
  service_name                   = "${var.service_name}-sforce-sink"
  secret_name                    = "salesforce_credentials"
  secret_recovery_window_in_days = 7
}