provider "aws" {
  region = var.region
}

# Provider for failover bucket
provider "aws" {
  alias  = "aws_us_west_2"
  region = "us-west-2"
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/kdh-docs/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "kdh_docs_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "javascript"
  service_name       = "kdh-docs"
  application_family = var.application_family
}

data "aws_route53_zone" "domain" {
  name         = var.domain_name
  private_zone = true
}

# Reference existing cert
data "aws_acm_certificate" "certificate" {
  domain      = "*.${data.aws_route53_zone.domain.name}"
  statuses    = ["ISSUED"]
  most_recent = true
}

# Reference existing WAF
data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-${var.service_name}-cloudfront-waf-block"
  scope = "CLOUDFRONT"
}

# S3 Buckets
data "aws_s3_bucket" "bucket_primary" {
  bucket = "${var.environment}-orcd-cdn"
}

data "aws_s3_bucket" "bucket_failover" {
  bucket   = "${var.environment}-orcd-cdn-us-west01"
  provider = aws.aws_us_west_2
}

# Cloudfront distribution must have a response headers policy in cache behaviors
data "aws_cloudfront_response_headers_policy" "response_headers_policy" {
  name = "${var.environment}-default"
}

# Cloudfront

# Requires corresponding change to S3 bucket policies in orcd-cdn parent folder
resource "aws_cloudfront_origin_access_identity" "origin_access_identity_primary" {
  comment = "${var.environment}-${var.service_name}-${var.service_name_suffix}-primary-origin-access-identity"
}

resource "aws_cloudfront_origin_access_identity" "origin_access_identity_failover" {
  comment = "${var.environment}-${var.service_name}-${var.service_name_suffix}-failover-origin-access-identity"
}

resource "aws_cloudfront_function" "rewrite_default_index" {
  name    = "${var.environment}-${var.service_name}-${var.service_name_suffix}-rewrite-default-index"
  runtime = "cloudfront-js-1.0"
  comment = "${var.environment}-${var.service_name}-${var.service_name_suffix}-rewrite-default-index"
  publish = true
  code    = file("functions/rewrite-default-index.js")
}

resource "aws_cloudfront_function" "viewer_request" {
  name    = "${var.environment}-${var.service_name}-${var.service_name_suffix}-viewer-request"
  runtime = "cloudfront-js-1.0"
  comment = "${var.environment}-${var.service_name}-${var.service_name_suffix}-viewer-request"
  publish = true
  code    = file("functions/viewer-request.js")
}

resource "aws_cloudfront_distribution" "distribution" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  # checkov:skip=CKV_AWS_374:Ensure AWS CloudFront web distribution has geo restriction enabled.
  aliases             = ["${var.service_name_suffix}.${var.domain_name}"]
  comment             = "${var.environment}-${var.service_name}-${var.service_name_suffix}"
  enabled             = true
  is_ipv6_enabled     = true
  http_version        = "http2"
  price_class         = "PriceClass_All"
  web_acl_id          = data.aws_wafv2_web_acl.waf.arn
  default_root_object = "index.html"

  origin_group {
    origin_id = "s3_origin_group"

    failover_criteria {
      status_codes = [403, 500, 502, 503]
    }

    member {
      origin_id = "${var.environment}-orcd-cdn"
    }

    member {
      origin_id = "${var.environment}-orcd-cdn-us-west01"
    }
  }

  origin {
    domain_name = data.aws_s3_bucket.bucket_primary.bucket_domain_name
    origin_id   = "${var.environment}-orcd-cdn"
    origin_path = "/${var.service_name_suffix}"

    s3_origin_config {
      origin_access_identity = aws_cloudfront_origin_access_identity.origin_access_identity_primary.cloudfront_access_identity_path
    }
  }

  origin {
    domain_name = data.aws_s3_bucket.bucket_failover.bucket_domain_name
    origin_id   = "${var.environment}-orcd-cdn-us-west01"
    origin_path = "/${var.service_name_suffix}"

    s3_origin_config {
      origin_access_identity = aws_cloudfront_origin_access_identity.origin_access_identity_failover.cloudfront_access_identity_path
    }
  }

  default_cache_behavior {
    allowed_methods            = var.allowed_methods
    cached_methods             = var.cached_methods
    default_ttl                = var.default_ttl
    min_ttl                    = 0
    max_ttl                    = 604800
    compress                   = true
    target_origin_id           = "s3_origin_group"
    viewer_protocol_policy     = "redirect-to-https"
    response_headers_policy_id = data.aws_cloudfront_response_headers_policy.response_headers_policy.id

    forwarded_values {
      query_string = false

      cookies {
        forward = "none"
      }
    }

    function_association {
      event_type   = "viewer-request"
      function_arn = aws_cloudfront_function.rewrite_default_index.arn
    }

    function_association {
      event_type   = "viewer-request"
      function_arn = aws_cloudfront_function.viewer_request.arn
    }
  }

  restrictions {
    geo_restriction {
      restriction_type = "none"
    }
  }

  viewer_certificate {
    acm_certificate_arn      = data.aws_acm_certificate.certificate.arn
    ssl_support_method       = "sni-only"
    minimum_protocol_version = var.cloudfront_minimum_protocol_version
  }

  logging_config {
    include_cookies = true
    bucket          = var.cloudfront_logging_bucket
    prefix          = "${var.environment}-${var.service_name}-${var.service_name_suffix}"
  }

  tags = {
    environment         = var.environment
    service_name        = var.service_name
    service_name_suffix = var.service_name_suffix
    terraformed         = true
  }
}

resource "aws_route53_record" "route53_record" {
  name    = var.service_name_suffix
  zone_id = data.aws_route53_zone.domain.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [aws_cloudfront_distribution.distribution.domain_name]
}