provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/kollectivenr/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_kinesis_firehose_delivery_stream" "stream" {
  name = "aws-waf-logs-tf-orcd-prod-stream"
}

data "aws_route53_zone" "zone" {
  name         = var.domain_name
  private_zone = false
}

resource "aws_acm_certificate" "tls_cert" {
  # checkov:skip=CKV2_AWS_71: Ensure AWS ACM Certificate domain name does not include wildcards
  domain_name               = "*.${data.aws_route53_zone.zone.name}"
  subject_alternative_names = [data.aws_route53_zone.zone.name]
  validation_method         = "DNS"

  options {
    certificate_transparency_logging_preference = "ENABLED"
  }

  tags = {
    environment  = var.environment
    service_name = var.service_name
    terraformed  = "true"
  }

  lifecycle {
    create_before_destroy = true
  }
}

resource "aws_route53_record" "dns_validation_record" {
  for_each = {
    for validation_object in aws_acm_certificate.tls_cert.domain_validation_options : validation_object.domain_name => {
      name   = validation_object.resource_record_name
      record = validation_object.resource_record_value
      type   = validation_object.resource_record_type
    }
  }

  allow_overwrite = true
  name            = each.value.name
  records         = [each.value.record]
  ttl             = 60
  type            = each.value.type
  zone_id         = data.aws_route53_zone.zone.zone_id
}

resource "aws_acm_certificate_validation" "certificate_validation" {
  certificate_arn         = aws_acm_certificate.tls_cert.arn
  validation_record_fqdns = [for record in aws_route53_record.dns_validation_record : record.fqdn]
}

# Add WAF for Cloudfront distribution
module "cloudfront_waf" {
  source            = "git@github.com:theorchard/terraform-aws-waf.git//?ref=2.0.0"
  environment       = var.environment
  service_name      = var.service_name
  aws_region        = var.aws_region
  acl_scope         = "CLOUDFRONT"
  count_waf_enabled = false
  block_waf_enabled = true
}