data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
        "arn:aws:iam::437795906767:user/cucumber-tests",
      ]
    }
  }
}


# QA ONLY: iam secrets manager policy for integration tests jenkins job
module "lambda_abacus_integration_test_secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.4.0"

  secrets = [
    "${var.environment}/${var.service_name}-commit-royalties/INTEGRATION_TEST_SNOWFLAKE_KEY_PASSPHRASE",
    "${var.environment}/${var.service_name}-commit-royalties/INTEGRATION_TEST_SNOWFLAKE_PRIVATE_KEY",

    "${var.environment}/${var.service_name}-correction-stage/INTEGRATION_TEST_SNOWFLAKE_KEY_PASSPHRASE",
    "${var.environment}/${var.service_name}-correction-stage/INTEGRATION_TEST_SNOWFLAKE_PRIVATE_KEY",

    "${var.environment}/${var.service_name}-ledger-accounting-run-balance/INTEGRATION_TEST_SNOWFLAKE_KEY_PASSPHRASE",
    "${var.environment}/${var.service_name}-ledger-accounting-run-balance/INTEGRATION_TEST_SNOWFLAKE_PRIVATE_KEY",

    "${var.environment}/${var.service_name}-reserves-take/INTEGRATION_TEST_SNOWFLAKE_KEY_PASSPHRASE",
    "${var.environment}/${var.service_name}-reserves-take/INTEGRATION_TEST_SNOWFLAKE_PRIVATE_KEY",

    "${var.environment}/${var.service_name}-commit-mechanicals/INTEGRATION_TEST_SNOWFLAKE_KEY_PASSPHRASE",
    "${var.environment}/${var.service_name}-commit-mechanicals/INTEGRATION_TEST_SNOWFLAKE_PRIVATE_KEY",

    "${var.environment}/${var.service_name}-snapshot-contracts/INTEGRATION_TEST_SNOWFLAKE_KEY_PASSPHRASE",
    "${var.environment}/${var.service_name}-snapshot-contracts/INTEGRATION_TEST_SNOWFLAKE_PRIVATE_KEY",

    "qa/${var.service_name}-schedule-auto-add/M2M_JWT_ACCESS_TOKEN",
    "qa/${var.service_name}-schedule-auto-add/SENTRY_DSN",

    "${var.environment}/${var.service_name}-integration-tests/MYSQL_PASS",
    "${var.environment}/${var.service_name}-integration-tests/TEST_USER_AWS_ACCESS_KEY_ID",
    "${var.environment}/${var.service_name}-integration-tests/TEST_USER_AWS_SECRET_ACCESS_KEY",
    "${var.environment}/${var.service_name}-integration-tests/SAP_AUTH_PASSWORD",
  ]

  action_types = ["read"]

  depends_on = [
    module.lambda_abacus_commit_royalties_secrets,
    module.lambda_abacus_correction_stage_secrets,
    module.lambda_abacus_ledger_accounting_run_balance_secrets,
    module.lambda_abacus_reserves_take_secrets
  ]
}


resource "aws_iam_policy" "lambda_abacus_integration_test_secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-integration-test-policy"
  policy = module.lambda_abacus_integration_test_secrets_manager_policy.policy.json

  tags = {
    environment        = var.environment
    application_family = var.application_family
    service_name       = var.service_name
  }
}


resource "aws_iam_role" "lambda_abacus_integration_test_role" {
  name               = "${var.environment}-${var.service_name}-integration-test-role"
  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json

  tags = {
    environment        = var.environment
    application_family = var.application_family
    service_name       = var.service_name
  }
}


resource "aws_iam_role_policy_attachment" "lambda_abacus_integration_test_role_policy_attachment" {
  role       = aws_iam_role.lambda_abacus_integration_test_role.name
  policy_arn = aws_iam_policy.lambda_abacus_integration_test_secrets_manager_policy.arn
}

module "lambda_abacus_integration_tests_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.integration_tests_secrets)

  application_family = var.application_family
  environment        = var.environment
  service_name       = "${var.service_name}-integration-tests"
  secret_name        = each.value
}