locals {
  lambda_abacus_json_contract_file_import_service_name = "${var.service_name}-json-contract-file-import"
}

module "s3_qa_json_contract_file_import_bucket" {
  source              = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.15.1"
  env                 = var.environment
  bucket_name         = var.json_contract_file_import_bucket_name
  kms_key_enabled     = false
  application_family  = var.application_family
  s3_read_only_policy = true

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

data "aws_iam_policy_document" "abacus_json_contract_file_import_bucket_read_write_access_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject*",
      "s3:HeadObject",
      "s3:ListObject*",
      "s3:PutObject*",
      "s3:DeleteObject*"
    ]

    resources = [
      "${module.s3_qa_json_contract_file_import_bucket.s3_bucket_arn_output}/*",
      "${module.s3_qa_json_contract_file_import_bucket.s3_bucket_arn_output}/",
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "s3:GetBucketLocation",
      "s3:ListBucket",
      "s3:ListBucketVersions"
    ]

    resources = [
      module.s3_qa_json_contract_file_import_bucket.s3_bucket_arn_output
    ]
  }
}

resource "aws_iam_policy" "abacus_json_contract_file_import_bucket_read_write_access_policy" {
  name        = "${var.environment}-abacus-json-contract-file-import-read-write-access-policy"
  description = "Policy for json_contract_import_file bucket read/write permissions"
  policy      = data.aws_iam_policy_document.abacus_json_contract_file_import_bucket_read_write_access_document.json
}

module "lambda_abacus_json_contract_file_import_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = local.lambda_abacus_json_contract_file_import_service_name
  teams              = ["abacus-${var.environment}"]
  application_family = var.application_family
}

module "lambda_abacus_json_contract_file_import_owsrequest" {
  source           = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"
  environment_name = var.environment
  service_name     = local.lambda_abacus_json_contract_file_import_service_name
}

module "lambda_abacus_json_contract_file_import" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment                                       = var.environment
  lambda_function_timeout                           = 900
  use_container_image                               = true
  lambda_description                                = "Import contracts from JSON files in S3."
  lambda_name                                       = "lambda-abacus-json-contract-file-import"
  vpc_id                                            = module.vpc_info.vpc_id
  vpc_subnet_ids                                    = module.vpc_info.default_private_subnet_ids
  vpc_create_security_group                         = true
  application_family                                = var.application_family
  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions

  lambda_function_reserved_concurrent_executions = 6
  lambda_function_memory_size                    = 10240

  datadog_enabled          = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT    = var.environment
    MYSQL_DB_NAME  = var.lambda_abacus_mysql_database
    MYSQL_DB_HOST  = var.lambda_abacus_mysql_host
    MYSQL_DB_USER  = var.lambda_abacus_mysql_user
    S3_BUCKET_NAME = "${var.environment}-${var.json_contract_file_import_bucket_name}"
  }

  iam_managed_policy_attachments = [
    module.lambda_abacus_json_contract_file_import_owsrequest.policy_arn_output,
    aws_iam_policy.abacus_json_contract_file_import_bucket_read_write_access_policy.arn
  ]
}

module "lambda_abacus_json_contract_file_import_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = local.lambda_abacus_json_contract_file_import_service_name
  secret_name        = each.value
}

# For the integration tests
data "aws_s3_bucket" "json_contract_file_import_bucket" {
  bucket = "${var.environment}-${var.json_contract_file_import_bucket_name}"
}

data "aws_iam_policy_document" "s3_json_contract_file_import_bucket_rw_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "s3:GetBucketLocation",
      "s3:ListBucket",
      "s3:ListBucketVersions",
    ]
    resources = [
      data.aws_s3_bucket.json_contract_file_import_bucket.arn,
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:DeleteObject",
    ]
    resources = [
      "${data.aws_s3_bucket.json_contract_file_import_bucket.arn}/*",
    ]
  }
}

resource "aws_iam_policy" "s3_json_contract_file_import_bucket_rw_policy" {
  name   = "S3-${data.aws_s3_bucket.json_contract_file_import_bucket.id}-RW-policy"
  policy = data.aws_iam_policy_document.s3_json_contract_file_import_bucket_rw_policy_document.json
}

resource "aws_iam_user_policy_attachment" "s3_bucket_rw_policy_attachment" {
  user       = "cucumber-tests"
  policy_arn = aws_iam_policy.s3_json_contract_file_import_bucket_rw_policy.arn
}