module "bulk_asset_download_output_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.12.0"

  bucket_name        = "bulk-asset-download-output"
  env                = var.environment
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  lifecycle_rules_options_noncurrent_version_expiration = [
    {
      prefix = ""
      enabled = true
      days = 1
    }
  ]

  lifecycle_rules_options_current_version_expiration = [
    {
      prefix  = ""
      enabled = true
      days    = 42
    },
  ]

  lifecycle_rules_expired_object_delete_markers_expiration = [
    {
      prefix  = ""
      enabled = true
    },
  ]
}

data "aws_iam_policy_document" "s3_bulk_asset_download_output_bucket_access_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:ListBucket"
    ]

    resources = [
      module.bulk_asset_download_output_bucket.s3_bucket_arn_output,
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "s3:PutObject",
      "s3:HeadObject",
      "s3:GetObject",
      "s3:DeleteObject",
    ]

    resources = [
      format("%s/*", module.bulk_asset_download_output_bucket.s3_bucket_arn_output),
    ]
  }
}

resource "aws_iam_policy" "s3_bulk_asset_download_output_bucket_access_policy" {
  name        = format("S3-%s-%s-output-bucket-RW", var.environment, local.sfn_name)
  description = "Read and write to bulk-asset-download-output buckets"
  policy      = data.aws_iam_policy_document.s3_bulk_asset_download_output_bucket_access_policy_document.json
}

module "bulk_asset_download_input_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.12.0"

  bucket_name        = "bulk-asset-download-input"
  env                = var.environment
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  lifecycle_rules_options_noncurrent_version_expiration = [
    {
      prefix = ""
      enabled = false
      days = 365
    }
  ]

  lifecycle_rules_options_current_version_expiration = [
    {
      prefix  = ""
      enabled = false
      days    = 365
    },
  ]

  lifecycle_rules_expired_object_delete_markers_expiration = [
    {
      prefix  = ""
      enabled = false
    },
  ]
}

data "aws_iam_policy_document" "s3_bulk_asset_download_input_bucket_access_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:ListBucket"
    ]

    resources = [
      module.bulk_asset_download_input_bucket.s3_bucket_arn_output,
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "s3:PutObject",
      "s3:HeadObject",
      "s3:GetObject",
      "s3:ListMultipartUploadParts",
      "s3:AbortMultipartUpload",
      "s3:DeleteObject",
    ]

    resources = [
      format("%s/%s", module.bulk_asset_download_input_bucket.s3_bucket_arn_output, "*"),
    ]
  }
}

resource "aws_iam_policy" "s3_bulk_asset_download_input_bucket_access_policy" {
  name        = format("S3-%s-%s-input-bucket-RW", var.environment, local.sfn_name)
  description = "Read and write to bulk-asset-download-input buckets"
  policy      = data.aws_iam_policy_document.s3_bulk_asset_download_input_bucket_access_policy_document.json
}