provider "aws" {
  region = "us-east-1"
}

data "aws_caller_identity" "current" {}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/lambda-av-scan-containerized/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_iam_policy_document" "lambda_av_scan_containerized_policy_document" {
  statement {
    effect = "Allow"
    resources = [
    "arn:aws:s3:::*"]
    actions = ["s3:ListAllMyBuckets"]
  }

  statement {
    sid    = ""
    effect = "Allow"
    resources = formatlist(
      "arn:aws:s3:::%s/*",
      concat(var.bucket_names, [module.integration_test_bucket.s3_bucket_name_output])
    )

    actions = [
      "s3:GetBucketAcl",
      "s3:GetObject",
      "s3:GetObjectAcl",
      "s3:GetObjectVersion",
      "s3:GetObjectVersionAcl",
      "s3:DeleteObject",
      "s3:PutObject",
      "s3:PutObjectAcl",
      "s3:PutObjectVersionAcl",
    ]
  }
}

resource "aws_iam_policy" "lambda_av_scan_containerized_policy" {
  name        = "${var.environment}-av-scan-lambda-containerized-policy"
  description = "Policy for lambda-av-scan-containerized"
  policy      = data.aws_iam_policy_document.lambda_av_scan_containerized_policy_document.json
}

module "lambda_av_scan_containerized_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.0.1"

  environment_name = var.environment
  service_name     = var.lambda_name
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

module "lambda_av_scan_containerized" {
  source                                            = "git@github.com:theorchard/terraform-lambda.git?ref=3.1.4"
  lambda_name                                       = var.lambda_name
  environment                                       = var.environment
  application_family                                = var.application_family
  lambda_function_memory_size                       = var.lambda_memory_size
  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions
  lambda_function_reserved_concurrent_executions    = var.lambda_concurrent_executions
  lambda_function_timeout                           = var.lambda_default_timeout
  use_container_image                               = true
  vpc_id                                            = module.vpc_info.vpc_id
  vpc_subnet_ids                                    = module.vpc_info.default_private_subnet_ids
  iam_managed_policy_attachments = [
    aws_iam_policy.lambda_av_scan_containerized_policy.arn,
    module.lambda_av_scan_containerized_owsrequest.policy_arn_output
  ]
  lambda_function_environment_variables = {
    ENVIRONMENT         = var.environment
    KAFKA_BROKERS       = join(",", var.kafka_brokers)
    KAFKA_CLIENT_ID     = "lambda-av-scan"
    NR_KAFKA_TOPIC      = var.nr_kafka_topic
    SCHEMA_REGISTRY_URL = var.schema_registry_url
  }
  datadog_function_destination_lambda_name = "DatadogLambdaFunction"
}

module "lambda_av_scan_sentry_project" {
  source             = "git@github.com:theorchard/terraform-sentry//?ref=4.1.0"
  service_name       = var.lambda_name
  environment        = var.environment
  application_family = var.application_family
  platform           = "python"
}

# Create IAM user for jenkins lambda-av-scan-update-definitions job.
resource "aws_iam_user" "iam_av_scan_update_definitions_user" {
  name = "${var.environment}-av-scan-update-definitions-user"
  tags = {
    terraformed = true
    role        = "service-user"
  }
}

# Attach iam policies to av-scan-update-definitions_user iam user.
resource "aws_iam_user_policy_attachment" "iam_user_policy_attachment" {
  for_each = toset([
    "arn:aws:iam::437795906767:policy/S3-qa-orcd-cdn-frontend-podcast-RW",
  ])

  policy_arn = each.value
  user       = aws_iam_user.iam_av_scan_update_definitions_user.name
}