provider "aws" {
  region = "us-east-1"
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/lambda-collaborator/payoneer-status-sync/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

module "collaborator_payoneer_status_sync" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.3.0"

  application_family        = var.application_family
  use_container_image       = true
  environment               = var.environment
  lambda_name               = var.lambda_name
  vpc_subnet_ids            = slice(module.vpc_info.default_private_subnet_ids, 0, 2)
  vpc_id                    = module.vpc_info.vpc_id
  vpc_create_security_group = true

  lambda_description      = "Syncs Payoneer payout statuses back to DP payment records"
  lambda_function_handler = "index.handler"
  lambda_function_timeout = 900

  lambda_function_environment_variables = {
    ENVIRONMENT                   = var.environment
    DB_COLLABORATORS_HOST         = var.db_collaborators_host
    DB_COLLABORATORS_USERNAME     = "collab_env"
    PAYONEER_AUTH_TOKEN_SECRET_ID = "${var.environment}/ows-payee/payoneer_auth_token"
    DD_ENV                        = var.environment
    DD_SERVICE                    = var.lambda_name
    SENTRY_DSN                    = module.sentry_project.sentry_key_dsn_public_output
  }

  datadog_advanced_enabled                 = true
  datadog_function_destination_lambda_name = "DatadogLambdaFunction"
}

data "aws_iam_policy_document" "lambda_execution_iam_policy_document" {
  statement {
    actions = [
      "secretsmanager:GetSecretValue",
    ]

    resources = [for secret in module.secrets : secret.secret_arn]
  }

  statement {
    actions = [
      "secretsmanager:GetSecretValue",
    ]

    resources = [
      "arn:aws:secretsmanager:us-east-1:${data.aws_caller_identity.current.account_id}:secret:${var.environment}/ows-payee/payoneer_auth_token*"
    ]
  }
}

resource "aws_iam_role_policy" "lambda_execution_iam_policy" {
  role   = module.collaborator_payoneer_status_sync.lambda_role_id
  policy = data.aws_iam_policy_document.lambda_execution_iam_policy_document.json
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = var.lambda_name
  secret_name        = each.value
  application_family = var.application_family
}

module "sentry_project" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"
  service_name       = var.lambda_name
  environment        = var.environment
  platform           = "python"
  application_family = var.application_family
}