provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/lambda-content/apple-style-guide-validator/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

locals {
  sfn_name = "sfn-content-apple-sg-validator"
}

resource "aws_cloudwatch_log_group" "sfn_log_group" {
  name              = "/aws/vendedlogs/states/${var.environment}-${local.sfn_name}-log-group"
  retention_in_days = 365
  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = local.sfn_name
    terraformed        = true
  }
}

# Step Function (SFN) - SFN Cloudwatch logs permission policy
data "aws_iam_policy_document" "sfn_apple_sg_validator_log_event_policy_document" {
  # checkov:skip=CKV_AWS_111:not all Cloudwatch API actions support resources types
  statement {
    effect = "Allow"
    resources = [
      "arn:aws:logs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:log-group:${var.environment}-${local.sfn_name}",
      "arn:aws:logs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:log-group:${var.environment}-${local.sfn_name}:log-stream:*",
      "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    ]

    actions = [
      "logs:CreateLogGroup",
      "logs:CreateLogStream",
      "logs:PutLogEvents"
    ]
  }

  statement {
    effect    = "Allow"
    resources = ["*"]
    actions = [
      "logs:CreateLogDelivery",
      "logs:DeleteLogDelivery",
      "logs:DescribeLogGroups",
      "logs:DescribeResourcePolicies",
      "logs:GetLogDelivery",
      "logs:ListLogDeliveries",
      "logs:PutResourcePolicy",
      "logs:UpdateLogDelivery",
      "logs:DeleteLogGroup",
      "logs:DeleteLogStream"
    ]
  }
}
resource "aws_iam_policy" "sfn_apple_sg_validator_log_event_policy" {
  name        = "${var.environment}-${local.sfn_name}-log-event-policy"
  description = "Policy for Step Function to write logs to CloudWatch"
  policy      = data.aws_iam_policy_document.sfn_apple_sg_validator_log_event_policy_document.json
}

resource "aws_iam_role_policy_attachment" "sfn_apple_sg_validator_log_event_policy_attachment" {
  role       = aws_iam_role.sfn_apple_sg_validator_assume_role.name
  policy_arn = aws_iam_policy.sfn_apple_sg_validator_log_event_policy.arn
}

data "aws_iam_policy_document" "sfn_apple_sg_validator_assume_role" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "Service"
      identifiers = [
        "states.amazonaws.com",
        "events.amazonaws.com"
      ]
    }
  }
}

resource "aws_iam_role" "sfn_apple_sg_validator_assume_role" {
  name               = "${var.environment}-${local.sfn_name}-state-machine-role"
  assume_role_policy = data.aws_iam_policy_document.sfn_apple_sg_validator_assume_role.json
}

data "aws_iam_policy_document" "sfn_apple_sg_validator_bedrock" {
  statement {
    actions = [
      "bedrock:InvokeModel",
    ]

    resources = [
      "arn:aws:bedrock:us-*::foundation-model/anthropic.claude-sonnet-4-6",
      "arn:aws:bedrock:us-*:${data.aws_caller_identity.current.account_id}:inference-profile/us.anthropic.claude-sonnet-4-6"
    ]
  }
}

resource "aws_iam_policy" "sfn_apple_sg_validator_bedrock" {
  name   = "Bedrock-${var.environment}-${local.sfn_name}-InvokeModel"
  policy = data.aws_iam_policy_document.sfn_apple_sg_validator_bedrock.json
}

resource "aws_iam_role_policy_attachment" "sfn_apple_sg_validator_bedrock" {
  role       = aws_iam_role.sfn_apple_sg_validator_assume_role.name
  policy_arn = aws_iam_policy.sfn_apple_sg_validator_bedrock.arn
}

data "aws_iam_policy_document" "sfn_apple_sg_validator_lambda" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_content_asgv_prepare_payload.lambda_arn,
      module.lambda_content_asgv_evaluate_results.lambda_arn
    ]
  }
}

resource "aws_iam_policy" "sfn_apple_sg_validator_lambda" {
  name   = "Lambda-${var.environment}-${local.sfn_name}-InvokeFunction"
  policy = data.aws_iam_policy_document.sfn_apple_sg_validator_lambda.json
}

resource "aws_iam_role_policy_attachment" "sfn_apple_sg_validator_lambda" {
  role       = aws_iam_role.sfn_apple_sg_validator_assume_role.name
  policy_arn = aws_iam_policy.sfn_apple_sg_validator_lambda.arn
}

data "template_file" "sfn_apple_sg_validator_definition" {
  template = file("${path.module}/sfn.json")

  vars = {
    REGION                      = var.aws_region
    ACCOUNT_ID                  = data.aws_caller_identity.current.account_id
    ENVIRONMENT                 = var.environment
    SYSTEM_PROMPT               = trimsuffix(trimprefix(jsonencode(file("${path.module}/system_prompt.md")), "\""), "\"")
    VALIDATOR_VERSION           = var.validator_version
    RESULTS_BUCKET              = module.apple_sg_validator_results_bucket.s3_bucket_name_output
    PREPARE_PAYLOAD_LAMBDA_ARN  = module.lambda_content_asgv_prepare_payload.lambda_arn
    EVALUATE_RESULTS_LAMBDA_ARN = module.lambda_content_asgv_evaluate_results.lambda_arn
  }
}

resource "aws_sfn_state_machine" "sfn_apple_sg_validator" {
  name       = "${var.environment}-${local.sfn_name}"
  role_arn   = aws_iam_role.sfn_apple_sg_validator_assume_role.arn
  definition = data.template_file.sfn_apple_sg_validator_definition.rendered

  tags = {
    application_family = var.application_family
    environment        = var.environment
    env                = var.environment
    service_name       = local.sfn_name
    service            = local.sfn_name
    DD_TRACE_ENABLED   = true
    terraformed        = true
  }
  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }
  tracing_configuration {
    enabled = true
  }
}

module "datadog_sfn_dashboard" {
  source                 = "git@github.com:theorchard/terraform-datadog.git//modules/step-function?ref=6.13.9"
  environment            = var.environment
  service_name           = local.sfn_name
  application_family     = var.application_family
  statemachine_arn       = aws_sfn_state_machine.sfn_apple_sg_validator.arn
  notification_endpoints = var.notification_endpoints
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.2.2"

  environment = var.environment
}