locals {
  index_queue_move_lambda_name = "${var.service_name}-index-queue-move"
}

module "lambda_content_index_queue_move" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.3.0"

  environment              = var.environment
  application_family       = var.application_family
  lambda_name              = local.index_queue_move_lambda_name
  lambda_description       = "Update properties of content review index when an item is moved to a different queue."
  vpc_id                   = module.vpc_info.vpc_id
  vpc_subnet_ids           = module.vpc_info.default_private_subnet_ids
  use_container_image      = true
  datadog_advanced_enabled = true

  iam_managed_policy_attachments = [
    data.aws_iam_policy.opensearch_rw_policy.arn,
  ]

  lambda_function_environment_variables = {
    ENVIRONMENT              = var.environment
    SENTRY_DSN               = module.sentry_lambda_content_index_queue_move.sentry_key_dsn_public_output
    SYSTEM_USER_IDENTITY_ID  = "482c79c3-bef7-4488-a746-cfe890cbc655"
    SYSTEM_USER_PROFILE_ID   = "660834"
    SYSTEM_USER_PROFILE_TYPE = "ContentProfile"
    OPENSEARCH_ENDPOINT      = var.os_domain_endpoint
    OPENSEARCH_PORT          = var.os_domain_port
    OPENSEARCH_INDEX_ALIAS   = var.opensearch_index_write_alias
  }

  msk_event_enabled                      = true
  event_source_mapping_msk_cluster_name  = var.trigger_msk_cluster_name
  event_source_mapping_msk_cluster_uuid  = var.trigger_msk_cluster_uuid
  event_source_mapping_batch_size        = 1
  kafka_topics                           = [var.content_review_product_topic]
  event_source_mapping_starting_position = "LATEST"
}

module "datadog_lambda_content_index_queue_move" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.9"

  environment                       = var.environment
  service_name                      = local.index_queue_move_lambda_name
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints
}

module "sentry_lambda_content_index_queue_move" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  service_name       = local.index_queue_move_lambda_name
  application_family = var.application_family
}