# Lambda definition for FingerprintAudio step

locals {
  fingerprint_lambda_name = "${var.lambda_name_prefix}-${var.service_name}-fingerprint"
}

data "aws_iam_policy" "s3_audio_readonly_policy" {
  name = "S3-${var.s3_audio_bucket}-RO"
}

module "lambda_content_match_audio_fingerprint" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.3.0"

  environment                            = var.environment
  application_family                     = var.application_family
  lambda_name                            = local.fingerprint_lambda_name
  lambda_description                     = "Fingerprint audio files."
  vpc_id                                 = module.vpc_info.vpc_id
  vpc_subnet_ids                         = module.vpc_info.default_private_subnet_ids
  use_container_image                    = true
  datadog_enabled                        = true
  datadog_advanced_enabled               = true
  lambda_function_ephemeral_storage_size = 10240
  lambda_function_memory_size            = 10240
  lambda_function_timeout                = 300

  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment
    SENTRY_DSN  = module.sentry_lambda_content_match_audio_fingerprint.sentry_key_dsn_public_output
  }

  iam_managed_policy_attachments = [
    data.aws_iam_policy.s3_audio_readonly_policy.arn
  ]

  # Added to fix datadog logging until ddtrace version can be upgraded
  datadog_advanced_merge_xray_traces_enabled = false
}

module "datadog_lambda_content_match_audio_fingerprint" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.9"

  environment                       = var.environment
  service_name                      = local.fingerprint_lambda_name
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints

  lambda_error_monitor_enabled      = false
  lambda_invocation_monitor_enabled = false
  lambda_throttle_monitor_enabled   = false
}

module "sentry_lambda_content_match_audio_fingerprint" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"

  environment        = var.environment
  service_name       = local.fingerprint_lambda_name
  application_family = var.application_family
}