data "aws_lambda_function" "lambda_grps_ingester_flow_control" {
  function_name = "grps-ingester-flow-control-qa"
}

data "aws_iam_policy_document" "grps_ingestor_flow_control_invoke_policy" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction",
    ]
    resources = [
      data.aws_lambda_function.lambda_grps_ingester_flow_control.arn,
    ]
  }
}

data "aws_iam_role" "prod_jenkins_aws_task_agent" {
  name = "prod-jenkins-aws-task-agent"
}

# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        data.aws_iam_role.prod_jenkins_aws_task_agent.arn,
      ]
    }
  }
}


# Jenkins agents will assume this role in order to invoke the flow control Lambdas
resource "aws_iam_role" "grps_ingestor_jenkins_invoke_role" {
  name               = "${var.environment}-grps-ingestor-control-jenkins-invoke-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

resource "aws_iam_policy" "grps_ingestor_flow_control_invoke_policy" {
  name   = "${var.environment}-grps-ingestor-flow-control-invoke-policy"
  policy = data.aws_iam_policy_document.grps_ingestor_flow_control_invoke_policy.json
}

# Attach invoke policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "grps_ingestor_flow_control_invoke_policy_attachment" {
  role       = aws_iam_role.grps_ingestor_jenkins_invoke_role.id
  policy_arn = aws_iam_policy.grps_ingestor_flow_control_invoke_policy.arn
}