module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

# Provider determines the method (AWS) and some basic provider properties
provider "aws" {
  region = var.region
  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/data-platform-grps-ingester/grps-ingestor-shared/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

module "secrets" {
  source             = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  environment        = var.environment
  service_name       = "${var.service_name}-${var.name}"
  secret_name        = "SNOWFLAKE_KEY"
  application_family = var.application_family
}

module "secrets_ddex_password" {
  source             = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  environment        = var.environment
  service_name       = "${var.service_name}-${var.name}"
  secret_name        = "DDEX_DB_RW_PASSWORD"
  application_family = var.application_family
}


data "aws_iam_policy_document" "sfn_grps_ingestor_secrets_manager_policy" {
  statement {
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}-${var.name}/SNOWFLAKE_KEY-*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}-${var.name}/DDEX_DB_RW_PASSWORD-*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/${var.service_name}-${var.name}/",
    ]
  }

  statement {
    actions = [
      "secretsmanager:GetRandomPassword",
    ]

    resources = [
      "*",
    ]
  }
}

resource "aws_iam_policy" "sfn_secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-${var.name}-policy"
  policy = data.aws_iam_policy_document.sfn_grps_ingestor_secrets_manager_policy.json
}

#use the same ddex folder on purpose
data "aws_s3_bucket" "s3_grps_ingester_lock_bucket" {
  bucket = "qa-ddex-ingester"
}

data "aws_iam_policy_document" "grps_locks_lambda_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "${data.aws_s3_bucket.s3_grps_ingester_lock_bucket.arn}/locks/*"
    ]

    actions = [
      "s3:DeleteObject",
      "s3:DeleteObjectVersion",
      "s3:PutObject",
      "s3:GetObject",
      "s3:HeadObject",
    ]
  }
}

resource "aws_iam_policy" "delete_locks_lambda_policy" {
  name        = "${var.environment}-grps-ingester-locks-lambda-policy"
  description = "Create/Delete locks grps-ingester lambda policy"
  policy      = data.aws_iam_policy_document.grps_locks_lambda_policy_document.json
}