module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

# Provider determines the method (AWS) and some basic provider properties
provider "aws" {
  region = var.region
  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/data-platform-grps-ingester/lambda-find-or-create-account/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_rds_cluster" "ddex_ingster_rds" {
  cluster_identifier = "${var.environment}-ddex-ingester"
}

data "aws_iam_policy" "sfn_secrets_manager_policy" {
  name = "SecretsManager-${var.environment}-${var.service_name}-shared-policy"
}

data "aws_iam_policy_document" "sfn_grps_ingestor_m2m_secret_policy_document" {
  statement {
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/ddex-ingester-find-or-create-account/M2M_*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/ddex-ingester-find-or-create-account/",
    ]
  }

  statement {
    actions = [
      "secretsmanager:GetRandomPassword",
    ]

    resources = [
      "*",
    ]
  }
}

resource "aws_iam_policy" "sfn_grps_ingestor_m2m_secret_policy" {
  name   = "SecretsManager-${var.environment}-ddex-create-account-m2m-policy"
  policy = data.aws_iam_policy_document.sfn_grps_ingestor_m2m_secret_policy_document.json
}


module "lambda_find_or_create_account" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.3.0"

  environment              = var.environment
  application_family       = var.application_family
  use_custom_function_name = true
  custom_function_name     = "${var.service_name}-${var.name}-${var.environment}"
  lambda_name              = "${var.service_name}-${var.name}"
  use_container_image      = true
  datadog_advanced_enabled = false

  lambda_function_environment_variables = {
    Environment         = var.environment
    LOGGER_DSN          = var.logger_dsn
    SENTRY_DSN          = module.sentry_find_or_create_account_lambda.sentry_key_dsn_public_output
    GRAPHQL_GATEWAY_URL = var.graphql_gateway_url
    OA_USER             = var.oa_user
    RDS_HOST            = data.aws_rds_cluster.ddex_ingster_rds.endpoint
    RDS_DB_NAME         = data.aws_rds_cluster.ddex_ingster_rds.database_name
    RDS_RW_USER         = var.rds_rw_user
    SNOWFLAKE_USER      = var.snowflake_user
    SNOWFLAKE_SCHEMA    = var.snowflake_schema
    SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    SNOWFLAKE_ACCOUNT   = var.snowflake_account
    SNOWFLAKE_DATABASE  = var.snowflake_database
    SNOWFLAKE_ROLE      = var.snowflake_role
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments = [
    data.aws_iam_policy.sfn_secrets_manager_policy.arn,
    aws_iam_policy.sfn_grps_ingestor_m2m_secret_policy.arn
  ]
}

module "sentry_find_or_create_account_lambda" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  service_name       = "${var.service_name}-${var.name}"
  application_family = var.application_family
}

module "m2m_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"

  environment        = var.environment
  service_name       = "${var.service_name}-${var.name}"
  application_family = var.application_family
}