# Provider determines the method (AWS) and some basic provider properties
provider "aws" {
  region = var.region
}

# Terraform backends cannot contain interpolations - of the form ${var.environment}-${var.service_name}-state
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/data-platform-grps-ingester/lambda-flow-control/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}


data "aws_sfn_state_machine" "sfn_grps_ingester_sfn" {
  name = "${var.environment}-grps-ingester-sfn"
}

data "aws_iam_policy" "sfn_secrets_manager_policy" {
  name = "SecretsManager-${var.environment}-${var.service_name}-shared-policy"
}

data "aws_iam_policy_document" "sfn_grps_ingester_role_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "states:StartExecution",
      "states:ListExecutions",
    ]
    resources = [
      data.aws_sfn_state_machine.sfn_grps_ingester_sfn.arn
    ]
  }
  statement {
    effect = "Allow"
    actions = [
      "states:DescribeExecution",
    ]
    # Execution ARNs use :execution: namespace instead of :stateMachine:
    # and require a wildcard suffix to cover all individual executions
    resources = [
      "${replace(data.aws_sfn_state_machine.sfn_grps_ingester_sfn.arn, ":stateMachine:", ":execution:")}:*"
    ]
  }
}

resource "aws_iam_policy" "sfn_grps_ingester_role_policy" {
  name   = "SFN-${var.environment}-grps-ingester-sfn-runner-role-policy"
  policy = data.aws_iam_policy_document.sfn_grps_ingester_role_policy_document.json
}

module "lambda_get_grps_data" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment              = var.environment
  application_family       = var.application_family
  use_custom_function_name = true
  custom_function_name     = "${var.service_name}-${var.name}-${var.environment}"
  lambda_name              = "${var.service_name}-${var.name}"
  use_container_image      = true
  datadog_advanced_enabled = false

  lambda_function_environment_variables = {
    Environment           = var.environment
    LOGGER_DSN            = var.logger_dsn
    SENTRY_DSN            = module.sentry_get_grps_data_lambda.sentry_key_dsn_public_output
    SNOWFLAKE_USER        = var.snowflake_user
    SNOWFLAKE_SCHEMA      = var.snowflake_schema
    SNOWFLAKE_WAREHOUSE   = var.snowflake_warehouse
    SNOWFLAKE_ACCOUNT     = var.snowflake_account
    SNOWFLAKE_DATABASE    = var.snowflake_database
    SNOWFLAKE_ROLE        = var.snowflake_role
    GRPS_INGESTER_SFN_ARN = data.aws_sfn_state_machine.sfn_grps_ingester_sfn.arn
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments = [
    aws_iam_policy.sfn_grps_ingester_role_policy.arn,
    data.aws_iam_policy.sfn_secrets_manager_policy.arn
  ]
}

module "sentry_get_grps_data_lambda" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  service_name       = "${var.service_name}-flow-control"
  application_family = var.application_family
}