data "aws_secretsmanager_secret" "rds_read_write_password" {
  name = "qa/ddex-ingester/rds_read_write_password"
}

data "aws_iam_policy_document" "common_lambda_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      data.aws_s3_bucket.s3_ddex_ingester_bucket.arn
    ]
    actions = [
      "s3:ListBucket"
    ]
  }

  statement {
    sid    = ""
    effect = "Allow"
    resources = [
      "${data.aws_s3_bucket.s3_ddex_ingester_bucket.arn}/*"
    ]

    actions = [
      "s3:GetObject",
      "s3:GetObjectAcl",
      "s3:HeadObject",
      "s3:PutObject",
    ]
  }
}

resource "aws_iam_policy" "common_lambda_policy" {
  name        = "${var.environment}-ddex-ingester-common-lambda-policy"
  description = "Common ddex-ingester lambda policy"
  policy      = data.aws_iam_policy_document.common_lambda_policy_document.json
}

data "aws_iam_policy_document" "delete_locks_lambda_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "${data.aws_s3_bucket.s3_ddex_ingester_bucket.arn}/locks/*"
    ]

    actions = [
      "s3:DeleteObject",
      "s3:DeleteObjectVersion",
    ]
  }
}

resource "aws_iam_policy" "delete_locks_lambda_policy" {
  name        = "${var.environment}-ddex-ingester-delete-locks-lambda-policy"
  description = "Delete locks ddex-ingester lambda policy"
  policy      = data.aws_iam_policy_document.delete_locks_lambda_policy_document.json
}

data "aws_iam_policy_document" "rds_rw_password_secrets_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:GetSecretValue"
    ]
    resources = [
      data.aws_secretsmanager_secret.rds_read_write_password.arn
    ]
  }
}

resource "aws_iam_policy" "rds_rw_password_secrets_policy" {
  name   = "${var.environment}-${var.service_name}-rds-rw-password-secrets-policy"
  policy = data.aws_iam_policy_document.rds_rw_password_secrets_policy_document.json
}