# Provider determines the method (AWS) and some basic provider properties
provider "aws" {
  region = var.region
}

# Terraform backends cannot contain interpolations - of the form ${var.environment}-${var.service_name}-state
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ddex-ingester/lambda-fix-video-resolution/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

# Lambda defintion for 'Fix Video Resolution' step
module "lambda_fix_video_resolution" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment                 = var.environment
  application_family          = var.application_family
  use_custom_function_name    = true
  custom_function_name        = "${var.service_name}-fix-video-resolution-${var.environment}"
  lambda_name                 = "${var.service_name}-fix-video-resolution"
  lambda_description          = "Fix resolution of video asset and upload it to S3"
  use_container_image         = true
  datadog_advanced_enabled    = true
  lambda_function_timeout     = 900
  lambda_function_memory_size = 10240

  lambda_function_environment_variables = {
    Environment = var.environment
    LOGGER_DSN  = var.logger_dsn
    SENTRY_DSN  = module.sentry_fix_video_resolution_lambda.sentry_key_dsn_public_output
  }

  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/qa-ddex-ingester-common-lambda-policy"
  ]
}

module "datadog_fix_video_resolution_lambda" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.16.0"

  environment                       = var.environment
  service_name                      = "${var.service_name}-fix-video-resolution"
  lambda_invocation_monitor_enabled = false
}


module "sentry_fix_video_resolution_lambda" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  service_name       = "${var.service_name}-fix-video-resolution"
  application_family = var.application_family
}