# Provider determines the method (AWS) and some basic provider properties
provider "aws" {
  region = var.region
}

# Terraform backends cannot contain interpolations - of the form ${var.environment}-${var.service_name}-state
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ddex-ingester/lambda-handle-artwork/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_s3_bucket" "raw_asset_bucket" {
  bucket = "qa-orcd-raw-assets"
}

data "aws_iam_policy_document" "handle_artwork_lambda_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "${data.aws_s3_bucket.raw_asset_bucket.arn}/*"
    ]

    actions = [
      "s3:PutObject"
    ]
  }
}

resource "aws_iam_policy" "handle_artwork_lambda_policy" {
  name        = "${var.environment}-ddex-ingester-handle-artwork-lambda-policy"
  description = "handle_artwork ddex-ingester lambda policy"
  policy      = data.aws_iam_policy_document.handle_artwork_lambda_policy_document.json
}

module "lambda_handle_artwork" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment                 = var.environment
  application_family          = var.application_family
  use_custom_function_name    = true
  custom_function_name        = "${var.service_name}-handle-artwork-${var.environment}"
  lambda_name                 = "${var.service_name}-handle-artwork"
  lambda_description          = "Handles product artwork"
  lambda_function_memory_size = 2048
  use_container_image         = true
  datadog_advanced_enabled    = true

  lambda_function_environment_variables = {
    Environment         = var.environment
    LOGGER_DSN          = var.logger_dsn
    SENTRY_DSN          = module.sentry_handle_artwork_lambda.sentry_key_dsn_public_output
    OA_USER             = var.oa_user
    GRAPHQL_GATEWAY_URL = var.graphql_gateway_url
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/qa-ddex-ingester-common-lambda-policy",
    aws_iam_policy.handle_artwork_lambda_policy.arn
  ]
}

module "datadog_handle_artwork_lambda" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.16.0"

  environment                       = var.environment
  service_name                      = "${var.service_name}-handle-artwork"
  lambda_invocation_monitor_enabled = false
}

module "sentry_handle_artwork_lambda" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  service_name       = "${var.service_name}-handle-artwork"
  application_family = var.application_family
}