# Provider determines the method (AWS) and some basic provider properties
provider "aws" {
  region = var.region
}

# Terraform backends cannot contain interpolations - of the form ${var.environment}-${var.service_name}-state
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ddex-ingester/lambda-lookup-switchboard-deal/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

data "aws_rds_cluster" "ddex_ingster_rds" {
  cluster_identifier = "qa-ddex-ingester"
}

resource "aws_security_group" "lambda_lookup_switchboard_deal_security_group" {
  name        = "lambda-lookup-switchboard-deal-${var.environment}-security-group"
  description = "Security group for lambda-lookup-switchboard-deal-${var.environment} in ${var.swb_vpc_id}"
  vpc_id      = var.swb_vpc_id

  tags = {
    environment = var.environment
    terraformed = true
    name        = "lambda-lookup-switchboard-deal-${var.environment}-security-group"
  }
}

resource "aws_security_group_rule" "allow_egress_for_lambda_lookup_switchboard_deal" {
  type              = "egress"
  from_port         = 0
  to_port           = 0
  protocol          = "-1"
  cidr_blocks       = ["0.0.0.0/0"]
  security_group_id = aws_security_group.lambda_lookup_switchboard_deal_security_group.id
}


module "lambda_lookup_switchboard_deal" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment              = var.environment
  application_family       = var.application_family
  use_custom_function_name = true
  custom_function_name     = "${var.service_name}-lookup-switchboard-deal-${var.environment}"
  lambda_name              = "${var.service_name}-lookup-switchboard-deal"
  lambda_description       = "Handles looking up the Switchboard deal for a product"
  use_container_image      = true
  datadog_advanced_enabled = true
  splitio_enabled          = true

  lambda_function_environment_variables = {
    Environment             = var.environment
    LOGGER_DSN              = var.logger_dsn
    SENTRY_DSN              = module.sentry_lookup_switchboard_deal_lambda.sentry_key_dsn_public_output
    OA_USER                 = var.oa_user
    GRAPHQL_GATEWAY_URL     = var.graphql_gateway_url
    SWITCHBOARD_ROLE_ARN    = var.swb_role_arn
    SWITCHBOARD_SECRET_ARN  = var.swb_secret_arn
    SWITCHBOARD_GRAPHQL_URL = var.swb_graphql_url
    RDS_HOST                = data.aws_rds_cluster.ddex_ingster_rds.endpoint
    RDS_DB_NAME             = data.aws_rds_cluster.ddex_ingster_rds.database_name
    RDS_RW_USER             = var.rds_rw_user
    SKIP_LAMBDA             = var.skip_lambda
    SPLIT_API_KEY_PATH      = "${var.environment}/split/API_KEY"
  }

  lambda_function_timeout = var.lambda_default_timeout

  vpc_id                                         = var.swb_vpc_id
  vpc_subnet_ids                                 = var.swb_vpc_subnet_ids
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/qa-ddex-ingester-common-lambda-policy",
    "arn:aws:iam::437795906767:policy/qa-switchboard-cross-account-assume-role-policy",
    "arn:aws:iam::437795906767:policy/qa-ddex-ingester-rds-rw-password-secrets-policy"
  ]
}

module "datadog_lookup_switchboard_deal_lambda" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.16.0"

  environment                       = var.environment
  service_name                      = "${var.service_name}-lookup-switchboard-deal"
  lambda_invocation_monitor_enabled = false
}

module "sentry_lookup_switchboard_deal_lambda" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  service_name       = "${var.service_name}-lookup-switchboard-deal"
  application_family = var.application_family
}