# Provider determines the method (AWS) and some basic provider properties
provider "aws" {
  region = var.region
}

# Terraform backends cannot contain interpolations - of the form ${var.environment}-${var.service_name}-state
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ddex-ingester/lambda-sme-analytics-ingestion-flow-control/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_sfn_state_machine" "sfn_sme_analytics" {
  name = "qa-sme-analytics-ddex-ingester-sfn"
}

data "aws_rds_cluster" "ddex_ingster_rds" {
  cluster_identifier = "qa-ddex-ingester"
}


data "aws_iam_policy_document" "sme_analytics_ingestion_flow_control_sfn_lambda_policy_document" {
  statement {
    actions = [
      "states:StartExecution",
      "states:ListExecutions",
      "states:GetExecutionHistory",
      "states:UpdateStateMachine",
      "states:DescribeStateMachine",
    ]

    resources = [
      data.aws_sfn_state_machine.sfn_sme_analytics.arn,
    ]
  }
}

resource "aws_iam_policy" "sme_analytics_ingestion_flow_control_sfn_lambda_policy" {
  name        = "${var.environment}-${var.service_name}-sme-analytics-ingestion-flow-control-lambda-sfn-policy"
  description = "trigger_state_machine ddex-ingester lambda policy"
  policy      = data.aws_iam_policy_document.sme_analytics_ingestion_flow_control_sfn_lambda_policy_document.json
}

module "lambda_sme_analytics_ingestion_flow_control" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.1"

  environment              = var.environment
  application_family       = var.application_family
  use_custom_function_name = true
  lambda_name              = "${var.service_name}-sme-analytics-ingestion-flow-control"
  custom_function_name     = "${var.service_name}-sme-analytics-ingestion-flow-control-${var.environment}"
  lambda_description       = "Handles Sme Analytics ingestion flow control"
  use_container_image      = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    Environment           = var.environment
    LOGGER_DSN            = var.logger_dsn
    SENTRY_DSN            = module.sentry_sme_analytics_ingestion_flow_control_lambda.sentry_key_dsn_public_output
    RDS_HOST              = data.aws_rds_cluster.ddex_ingster_rds.endpoint
    RDS_DB_NAME           = data.aws_rds_cluster.ddex_ingster_rds.database_name
    RDS_RW_USER           = var.rds_rw_user
    SME_ANALYTICS_SFN_ARN = data.aws_sfn_state_machine.sfn_sme_analytics.arn
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids
  lambda_function_reserved_concurrent_executions = 1
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/qa-ddex-ingester-common-lambda-policy",
    "arn:aws:iam::437795906767:policy/qa-ddex-ingester-rds-rw-password-secrets-policy",
    aws_iam_policy.sme_analytics_ingestion_flow_control_sfn_lambda_policy.arn,
  ]
}

module "datadog_sme_analytics_ingestion_flow_control_lambda" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.16.0"

  environment                       = var.environment
  service_name                      = "${var.service_name}-sme-analytics-ingestion-flow-control"
  lambda_invocation_monitor_enabled = false
}

module "sentry_sme_analytics_ingestion_flow_control_lambda" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  service_name       = "${var.service_name}-sme-analytics-flow-control"
  application_family = var.application_family
}


# QA only. Store db password for query test on mysql db
module "secrets" {
  source       = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  environment  = var.environment
  for_each     = toset(var.secrets_manager_secret_names)
  service_name = "${var.service_name}-sme-analytics-ingestion-flow-control"

  secret_name        = each.value
  application_family = var.application_family
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

data "aws_iam_policy_document" "ddex_ingester_sme_analytics_ingestion_secrets_policy" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetSecretValue",
    ]

    resources = [for s in values(module.secrets) : s.secret_arn]
  }
}

resource "aws_iam_policy" "ddex_ingester_secrets_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-sme-analytics-ingestion-policy"
  policy = data.aws_iam_policy_document.ddex_ingester_sme_analytics_ingestion_secrets_policy.json
}

resource "aws_iam_role" "ddex_ingester_sme_analytics_role" {
  name               = "${var.environment}-${var.service_name}-sme-analytics-ingestion-flow-control-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Attach SecretManager access policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "policy_attachment" {
  role       = aws_iam_role.ddex_ingester_sme_analytics_role.id
  policy_arn = aws_iam_policy.ddex_ingester_secrets_policy.arn
}

module "flow_control_datadog_monitoring" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.16.0"

  environment  = var.environment
  service_name = "${var.service_name}-sme-analytics-ingestion-flow-control"

  lambda_error_monitor_enabled      = true
  lambda_invocation_monitor_enabled = true

  lambda_error_ok_number                = 0
  lambda_error_warning_recovery_number  = null
  lambda_error_critical_recovery_number = null
  lambda_error_warning_number           = null
  lambda_error_critical_number          = 1

  lambda_invocation_time = "last_25m"

  notification_endpoints            = var.lambda_datadog_notification_endpoints
  escalation_notification_endpoints = var.lambda_datadog_notification_endpoints
}