provider "aws" {
  region = var.aws_region
}

data "aws_caller_identity" "current" {}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/lambda-distro-support/merge-label-participants/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source      = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.2.2"
  environment = var.environment
}

resource "aws_secretsmanager_secret" "neo4j_url" {
  name = "${var.environment}/${var.lambda_name}/NEO4J_URL"
}

resource "aws_secretsmanager_secret" "neo4j_username" {
  name = "${var.environment}/${var.lambda_name}/NEO4J_USERNAME"
}

resource "aws_secretsmanager_secret" "neo4j_password" {
  name = "${var.environment}/${var.lambda_name}/NEO4J_PASSWORD"
}

# for aura and split credentials
module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.6.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.lambda_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}


module "lambda_distro_support_merge_label_participants" {
  source = "git@github.com:theorchard/terraform-lambda.git?ref=3.1.4"

  application_family                             = var.application_family
  lambda_name                                    = var.lambda_name
  lambda_description                             = "Merge Label Participant nodes in neo4j"
  environment                                    = var.environment
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  lambda_function_timeout                        = var.lambda_default_timeout
  use_container_image                            = true
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids

  lambda_function_environment_variables = {
    Environment = var.environment
  }

  datadog_function_destination_lambda_name = "DatadogLambdaFunction"
}

# Lambda invoke policy document
data "aws_iam_policy_document" "lambda_invoke_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction"
    ]
    resources = [
      module.lambda_distro_support_merge_label_participants.lambda_arn
    ]
  }
}

# Lambda invoke policy
resource "aws_iam_policy" "lambda_invoke_policy" {
  name   = "Lambda-${var.environment}-${var.lambda_name}-invoke-only-policy"
  policy = data.aws_iam_policy_document.lambda_invoke_policy_document.json
}

# Lambda invokers group
resource "aws_iam_group" "merge_label_participants_group" {
  name = "${var.environment}-${var.lambda_name}-invokers-group"
}

# Attach policy to invokers group
resource "aws_iam_group_policy_attachment" "lambda_invokers_group_attach" {
  group      = aws_iam_group.merge_label_participants_group.name
  policy_arn = aws_iam_policy.lambda_invoke_policy.arn
}

# Add iam users to lambda-merge-label-participants-invokers-group iam group
resource "aws_iam_group_membership" "merge_label_participants_group_membership" {
  name = "lambda-merge-label-participants-invokers-group-membership"

  users = [
    "npatel",
  ]

  group = aws_iam_group.merge_label_participants_group.name
}

module "lambda_distro_support_merge_label_participant_sentry" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=5.1.0"

  application_family = var.application_family
  environment        = var.environment
  platform           = "python"
  service_name       = var.lambda_name
}