# Full auth0 config for SMF fan API
resource "aws_secretsmanager_secret" "smf_auth0_config" {
  name = "${var.environment}/${var.service_name}/SMF_AUTH0_CONFIG"
  tags = local.tags
}

# Full auth0 config for Tunespeak fan API
resource "aws_secretsmanager_secret" "tunespeak_auth0_config" {
  name = "${var.environment}/${var.service_name}/TUNESPEAK_AUTH0_CONFIG"
  tags = local.tags
}

# Full auth0 config for Wyng fan API
resource "aws_secretsmanager_secret" "wyng_auth0_config" {
  name = "${var.environment}/${var.service_name}/WYNG_AUTH0_CONFIG"
  tags = local.tags
}

# Full auth0 config for MTL fan API
resource "aws_secretsmanager_secret" "mtl_auth0_config" {
  name = "${var.environment}/${var.service_name}/MTL_AUTH0_CONFIG"
  tags = local.tags
}

data "aws_iam_policy_document" "secrets_manager_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetSecretValue",
    ]

    resources = [
      aws_secretsmanager_secret.smf_auth0_config.arn,
      aws_secretsmanager_secret.tunespeak_auth0_config.arn,
      aws_secretsmanager_secret.wyng_auth0_config.arn,
      aws_secretsmanager_secret.mtl_auth0_config.arn,
    ]
  }
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# SecretManager Access Policy
resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "${var.environment}-${var.service_name}-integration-tests-policy"
  policy = data.aws_iam_policy_document.secrets_manager_policy_document.json
}

# Jenkins agents will assume this role in order to access SecretManager
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "${var.environment}-${var.service_name}-integration-tests-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Attach SecretManager access policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "fan_api_integration_tests_secret_manager_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.secrets_manager_policy.arn
}