# Assume role policy used by Jenkins pipeline agent role
data "aws_iam_policy_document" "sks_leads_integration_test_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# Jenkins pipeline agents will assume this role
resource "aws_iam_role" "sks_leads_integration_tests_role" {
  name               = "${var.environment}-${var.lambda_name}-integration-tests-role"
  assume_role_policy = data.aws_iam_policy_document.sks_leads_integration_test_assume_role_policy.json
}

data "aws_iam_policy_document" "invoke_lambda_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.gda_sks_leads_lambda.lambda_arn,
    ]
  }
}

resource "aws_iam_role_policy" "sks_leads_integration_test_invoke_lambda_policy" {
  name   = "InvokeLambda-${var.environment}-${var.lambda_name}-policy"
  role   = aws_iam_role.sks_leads_integration_tests_role.id
  policy = data.aws_iam_policy_document.invoke_lambda_policy_document.json
}