module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git?ref=2.0.0"
  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
  team_name          = var.team
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

data "aws_caller_identity" "current" {}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/lambda-gda-sks-leads/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source      = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.2.2"
  environment = var.environment
}

module "secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset([
    "SALESFORCE_CONSUMER_KEY",
    "SALESFORCE_CONSUMER_SECRET",
    "SALESFORCE_REFRESH_TOKEN",
  ])

  environment                    = var.environment
  service_name                   = "lambda-${var.service_name}"
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}

module "gda_sks_leads_lambda_datadog" {
  source                            = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.10.7"
  environment                       = var.environment
  service_name                      = var.lambda_name
  lambda_invocation_monitor_enabled = false
}

data "aws_msk_cluster" "msk_cluster" {
  cluster_name = var.msk_cluster_name
}

module "gda_sks_leads_lambda" {
  source = "git@github.com:theorchard/terraform-lambda.git?ref=3.1.4"

  environment                                       = var.environment
  lambda_name                                       = var.lambda_name
  lambda_description                                = "Sync Leads from SalesForce into Kafka topic."
  application_family                                = var.application_family
  use_container_image                               = true
  lambda_function_provisioned_concurrent_executions = var.lambda_provisioned_concurrent_executions
  cloudwatch_event_enabled                          = true
  cloudwatch_event_schedule                         = var.cloudwatch_event_schedule
  datadog_advanced_enabled                          = var.datadog_advanced_enabled

  vpc_id                  = module.vpc_info.vpc_id
  vpc_subnet_ids          = module.vpc_info.default_private_subnet_ids
  dlq_enabled             = var.dlq_enabled
  zappa_s3_policy_enabled = false

  lambda_function_environment_variables = {
    environment        = var.environment
    BOOTSTRAP_SERVERS  = data.aws_msk_cluster.msk_cluster.bootstrap_brokers_tls
    KAFKA_TOPIC        = var.kafka_topic
    KAFKA_OFFSET_TOPIC = var.kafka_offset_topic
    GROUP_ID           = var.group_id
    SALESFORCE_DOMAIN  = var.salesforce_domain
    DD_LAMBDA_HANDLER  = var.lambda_handler
  }
}