data "aws_caller_identity" "current" {}

data "aws_iam_policy_document" "metadata-consistency-check-invoke-policy" {
  statement {
    effect = "Allow"
    actions = [
      "states:StartExecution"
    ]
    resources = [
      data.aws_sfn_state_machine.sfn_metadata_consistency_checks.arn
    ]
  }
}

# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

# SFN invoke policy.
resource "aws_iam_policy" "metadata_consistency_check_invoke_policy" {
  name   = "SFN-${var.environment}-metadata-consistency-check-invoke-policy"
  policy = data.aws_iam_policy_document.metadata-consistency-check-invoke-policy.json
}

# Jenkins agents will assume this role in order to invoke the machine
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "${var.environment}-metadata-consistency-check-jenkins-invoke-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

# Attach SFN invoke policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "metadata_consistency_check_invoke_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.metadata_consistency_check_invoke_policy.arn
}