data "aws_lambda_function" "datadog_lambda_function" {
  function_name = "DatadogLambdaFunction"
}

# Roles and permissions on sfn
data "aws_iam_policy_document" "assume_role_for_sfn_state_machine_policy_document" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "Service"

      identifiers = [
        "states.amazonaws.com",
        "lambda.amazonaws.com",
      ]
    }
  }
}

resource "aws_iam_role" "mcc_sfn_role" {
  name               = "${var.environment}-mcc-sfn-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_for_sfn_state_machine_policy_document.json
}

data "aws_iam_policy_document" "invoke_mcc_lambdas_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_get_product_metadata.lambda_arn,
      module.lambda_product_participations_check.lambda_arn,
      module.lambda_track_participations_check.lambda_arn,
      module.lambda_label_sound_recording_check.lambda_arn,
      module.lambda_fetch_track_participations.lambda_arn,
      module.lambda_fetch_product_participations.lambda_arn,
      module.lambda_fetch_track.lambda_arn,
      module.lambda_check_ddex_generation.lambda_arn,
      module.lambda_retry_sfn_execution.lambda_arn,
      var.lambda_kinesis_to_neo4j_arn
    ]
    effect = "Allow"
  }
}

resource "aws_iam_policy" "invoke_mcc_lambdas_policy" {
  name   = "Lambda-${var.environment}-mcc-invoke-policy"
  policy = data.aws_iam_policy_document.invoke_mcc_lambdas_policy_document.json
}

resource "aws_iam_role_policy_attachment" "invoke_mcc_lambdas_role_policy_attachment" {
  role       = aws_iam_role.mcc_sfn_role.name
  policy_arn = aws_iam_policy.invoke_mcc_lambdas_policy.arn
}

# Step Function cloudwatch logs permission policy
data "aws_iam_policy_document" "cloudwatch_log_event_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "${aws_cloudwatch_log_group.sfn_log_group.arn}:*",
    ]

    actions = [
      "logs:CreateLogStream",
      "logs:PutLogEvents",
    ]
  }

  statement {
    effect    = "Allow"
    resources = ["*"]
    actions = [
      "logs:CreateLogDelivery",
      "logs:DeleteLogDelivery",
      "logs:DescribeLogGroups",
      "logs:DescribeResourcePolicies",
      "logs:GetLogDelivery",
      "logs:ListLogDeliveries",
      "logs:PutResourcePolicy",
      "logs:UpdateLogDelivery",
    ]
  }
}


resource "aws_iam_policy" "sfn_log_event_policy" {
  name        = "${var.environment}-${var.sfn_service_name}-log-policy"
  description = "${var.environment}-${var.sfn_service_name}-log-policy"
  policy      = data.aws_iam_policy_document.cloudwatch_log_event_policy_document.json
}

resource "aws_iam_role_policy_attachment" "sfn_log_event_policy_attachment" {
  role       = aws_iam_role.mcc_sfn_role.name
  policy_arn = aws_iam_policy.sfn_log_event_policy.arn
}

resource "aws_cloudwatch_log_group" "sfn_log_group" {
  name              = "${var.environment}-${var.sfn_service_name}-log-group"
  retention_in_days = 365
  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.sfn_service_name
    terraformed        = true
  }
}

resource "aws_cloudwatch_log_subscription_filter" "datadog_lambda_log_filter" {
  name            = "${var.environment}-${var.sfn_service_name}-log-group-subscription-filter"
  log_group_name  = aws_cloudwatch_log_group.sfn_log_group.name
  filter_pattern  = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function.arn
  distribution    = "ByLogStream"
}

# Step Function template and definition
data "template_file" "mcc_state_machine_def" {
  template = file("${path.module}/metadata_consistency_checks_sfn.json")

  vars = {
    get_product_metadata_lambda_arn         = module.lambda_get_product_metadata.lambda_arn
    product_participations_check_lambda_arn = module.lambda_product_participations_check.lambda_arn
    track_participations_check_lambda_arn   = module.lambda_track_participations_check.lambda_arn
    label_sound_recording_check_lambda_arn  = module.lambda_label_sound_recording_check.lambda_arn
    fetch_product_participations_lambda_arn = module.lambda_fetch_product_participations.lambda_arn
    fetch_track_participations_lambda_arn   = module.lambda_fetch_track_participations.lambda_arn
    fetch_track_lambda_arn                  = module.lambda_fetch_track.lambda_arn
    lambda_kinesis_to_neo4j_arn             = var.lambda_kinesis_to_neo4j_arn
    ddex_check_lambda_arn                   = module.lambda_check_ddex_generation.lambda_arn
    handle_retry_lambda_arn                 = module.lambda_retry_sfn_execution.lambda_arn
  }
}

resource "aws_sfn_state_machine" "mcc_state_machine" {
  name       = "${var.environment}-${var.sfn_service_name}"
  role_arn   = aws_iam_role.mcc_sfn_role.arn
  definition = data.template_file.mcc_state_machine_def.rendered

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.sfn_service_name
    terraformed        = true
  }

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    include_execution_data = true
    level                  = "ERROR"
  }
  tracing_configuration {
    enabled = true
  }
}

# Datadog Dashboard
module "datadog_sfn_dashboard" {
  source             = "git@github.com:theorchard/terraform-datadog.git//modules/step-function?ref=6.10.0"
  environment        = var.environment
  service_name       = var.sfn_service_name
  application_family = var.application_family
  statemachine_arn   = aws_sfn_state_machine.mcc_state_machine.arn

  # failed log monitor
  failed_execution_message_log_monitor = {
    enabled        = true
    log_group_name = aws_cloudwatch_log_group.sfn_log_group.name
  }
  notification_endpoints            = "@slack-content-delivery-and-asset-mgmt-qa-alerts"
  escalation_notification_endpoints = "@slack-content-delivery-and-asset-mgmt-qa-alerts"
}