provider "aws" {
  region = var.aws_region

  default_tags {
    tags = {
      environment        = var.environment
      service_name       = var.service_name
      application_family = var.application_family
    }
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/lambda-moneyhub/integration-test/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

data "aws_caller_identity" "current" {}

data "aws_kms_key" "moneyhub_integration" {
  key_id = var.kms_key_id
}

data "aws_lambda_function" "invoke_lambda_moneyhub" {
  for_each      = toset(var.lambda_functions_to_access)
  function_name = each.value
}

data "aws_iam_policy_document" "integration_test_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction",
      "lambda:GetFunction",
    ]
    resources = flatten([
      for lambda in data.aws_lambda_function.invoke_lambda_moneyhub : [
        lambda.arn,
        "${lambda.arn}:*",
      ]
    ])
  }
}

resource "aws_iam_policy" "integration_test_policy" {
  name        = "${var.environment}-${var.service_name}-lambda-policy"
  description = "Allows invoking and inspecting moneyhub lambda functions for integration tests"
  policy      = data.aws_iam_policy_document.integration_test_policy_document.json
}

data "aws_iam_policy_document" "e2e_secrets_manager_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]
    resources = [
      "arn:aws:secretsmanager:${var.aws_region}:${data.aws_caller_identity.current.account_id}:secret:${var.environment}/e2e-test-secrets/db/royalty-accounting*",
    ]
  }
}

resource "aws_iam_policy" "e2e_secrets_manager_policy" {
  name        = "${var.environment}-${var.service_name}-secrets-manager-policy"
  description = "Allows reading e2e test secrets from Secrets Manager for moneyhub integration tests"
  policy      = data.aws_iam_policy_document.e2e_secrets_manager_policy_document.json
}

data "aws_iam_policy_document" "lambda_secrets_manager_policy_document" {
  statement {
    effect  = "Allow"
    actions = ["secretsmanager:GetSecretValue"]
    resources = [
      "arn:aws:secretsmanager:${var.aws_region}:${data.aws_caller_identity.current.account_id}:secret:${var.environment}/lambda-moneyhub-*",
      "arn:aws:secretsmanager:${var.aws_region}:${data.aws_caller_identity.current.account_id}:secret:${var.environment}/split/API_KEY*",
    ]
  }

  # Grant permission to decrypt Secrets Manager secrets encrypted with the moneyhub integration KMS key
  statement {
    effect    = "Allow"
    actions   = ["kms:Decrypt"]
    resources = [data.aws_kms_key.moneyhub_integration.arn]

    condition {
      test     = "StringEquals"
      variable = "kms:ViaService"
      values   = ["secretsmanager.${var.aws_region}.amazonaws.com"]
    }
  }
}

resource "aws_iam_policy" "lambda_secrets_manager_policy" {
  name        = "${var.environment}-${var.service_name}-lambda-secrets-policy"
  description = "Allows reading lambda runtime secrets from Secrets Manager for RIE integration tests"
  policy      = data.aws_iam_policy_document.lambda_secrets_manager_policy_document.json
}

# Assume role policy used by Jenkins scheduler agent role
data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# Jenkins agents will assume this role in order to invoke lambdas and access
# Secrets Manager
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "${var.environment}-${var.service_name}-role"
  description        = "Assumed by Jenkins pipeline agents to invoke moneyhub lambdas and access e2e test secrets"
  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "integration_test_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.integration_test_policy.arn
}

resource "aws_iam_role_policy_attachment" "e2e_secrets_manager_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.e2e_secrets_manager_policy.arn
}

resource "aws_iam_role_policy_attachment" "lambda_secrets_manager_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.lambda_secrets_manager_policy.arn
}

# Policy document to allow Jenkins to access moneyhub S3 buckets
data "aws_iam_policy_document" "s3_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject",
      "s3:PutObject",
      "s3:ListBucket",
      "s3:DeleteObject",
    ]

    resources = [
      "arn:aws:s3:::${var.environment}-moneyhub-attachments",
      "arn:aws:s3:::${var.environment}-moneyhub-attachments/*",
      "arn:aws:s3:::${var.environment}-moneyhub-custom-reports",
      "arn:aws:s3:::${var.environment}-moneyhub-custom-reports/*",
    ]
  }
}

# Policy to allow Jenkins to access moneyhub S3 buckets
resource "aws_iam_policy" "s3_policy" {
  name        = "${var.environment}-${var.service_name}-s3-policy"
  description = "Allows get, list, and delete on moneyhub S3 buckets for integration tests"
  policy      = data.aws_iam_policy_document.s3_policy_document.json
}

# Attach the S3 access policy to the Jenkins role
resource "aws_iam_role_policy_attachment" "s3_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.s3_policy.arn
}