# S3 bucket to store the results.
module "neo4j_monitor_s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.11.0"

  env                = var.environment
  bucket_name        = var.lambda_name
  application_family = var.application_family

  lifecycle_rules_options_current_version_expiration = [
    {
      enabled = true
      prefix  = var.s3_bucket_prefix
      days    = var.s3_bucket_objects_expiration_days
    }
  ]

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

# Lambda function to run neo4j queries and upload the results to S3.
module "neo4j_monitor_lambda" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.3.0"

  environment        = var.environment
  lambda_name        = var.lambda_name
  lambda_description = "Lambda function that runs custom queries on Neo4j and dumps results to stdout and S3."
  application_family = var.application_family

  use_container_image = true

  lambda_runtime                                 = var.lambda_runtime
  lambda_function_memory_size                    = var.lambda_memory_size
  lambda_function_timeout                        = var.lambda_timeout
  lambda_function_reserved_concurrent_executions = var.lambda_reserved_concurrent_executions
  lambda_function_publish_version                = var.lambda_publish_version
  lambda_function_handler                        = var.lambda_handler
  datadog_advanced_enabled                       = var.lambda_datadog_advanced_enable

  iam_managed_policy_attachments = [
    aws_iam_policy.neo4j_monitor_lambda_s3_access_policy.arn,
  ]

  lambda_function_environment_variables = {
    NEO4J_CREDENTIALS_SECRET_ARN = "arn:aws:secretsmanager:${var.aws_region}:${data.aws_caller_identity.current.account_id}:secret:${var.environment}/${var.lambda_name}/neo4j-credentials"
    S3_BUCKET_NAME               = module.neo4j_monitor_s3_bucket.s3_bucket_name_output
    S3_BUCKET_PREFIX             = var.s3_bucket_prefix
  }

  vpc_enabled    = true
  vpc_id                     = module.vpc_info.vpc_id
  vpc_subnet_ids             = module.vpc_info.default_private_subnet_ids

  dlq_enabled             = false
  zappa_s3_policy_enabled = false
}

# Lambda function permissions to access the S3 bucket.
resource "aws_iam_policy" "neo4j_monitor_lambda_s3_access_policy" {
  name   = "lambda-${var.environment}-${var.lambda_name}-s3-access-policy"
  policy = data.aws_iam_policy_document.neo4j_monitor_lambda_s3_access_policy.json
}

data "aws_iam_policy_document" "neo4j_monitor_lambda_s3_access_policy" {
  statement {
    effect = "Allow"

    actions = [
      "s3:PutObject"
    ]

    resources = [
      replace(format("arn:aws:s3:::%s/%s/*", module.neo4j_monitor_s3_bucket.s3_bucket_name_output, var.s3_bucket_prefix), "/\\/+/", "/")
    ]
  }
}

# Lambda invoke policy.
resource "aws_iam_policy" "neo4j_monitor_lambda_invoke_policy" {
  name   = "Lambda-${var.environment}-${var.lambda_name}-invoke-policy"
  policy = data.aws_iam_policy_document.neo4j_monitor_lambda_invoke_policy.json
}

data "aws_iam_policy_document" "neo4j_monitor_lambda_invoke_policy" {
  statement {
    effect = "Allow"

    actions = [
      "lambda:InvokeFunction"
    ]

    resources = [
      module.neo4j_monitor_lambda.lambda_arn
    ]
  }
}

# Jenkins agents will assume this role in order to invoke the function.
resource "aws_iam_role" "neo4j_monitor_jenkins_invoke_role" {
  name               = "${var.environment}-${var.lambda_name}-jenkins-invoke-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = [
      "sts:AssumeRole"
    ]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/prod-jenkins-aws-task-agent",
      ]
    }
  }
}

# Attach lambda invoke policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "neo4j_monitor_lambda_invoke_policy_attachment" {
  role       = aws_iam_role.neo4j_monitor_jenkins_invoke_role.id
  policy_arn = aws_iam_policy.neo4j_monitor_lambda_invoke_policy.arn
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.lambda_name
  secret_name        = each.value
}