# Integration test access policy document
data "aws_iam_policy_document" "integration_test_access_policy" {

  # Get secrets
  statement {
    effect = "Allow"

    # TODO: import secrets and reuse here
    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/publish-message/SEGMENT_WRITE_KEY*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/push-delivery-failure/SEGMENT_WRITE_KEY*"
    ]

    actions = [
      "secretsmanager:GetSecretValue"
    ]
  }

  # Invoke lambda
  statement {
    effect = "Allow"

    resources = [
      module.lambda_buffer_poller.lambda_arn,
      module.lambda-push-delivery-failure.lambda_arn,
      module.lambda_fanout_event.lambda_arn,
      module.lambda_publish_message.lambda_arn,
      module.lambda_notification_dispatcher.lambda_arn,
    ]

    actions = [
      "lambda:InvokeFunction"
    ]
  }
}


# Assume role policy document used by Jenkins
data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}


# Integration test access policy
resource "aws_iam_policy" "integration_test_access_policy" {
  name   = "${var.environment}-${var.service_name}-integration-test-access-policy"
  policy = data.aws_iam_policy_document.integration_test_access_policy.json
}


# Assume role policy used by Jenkins
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "${var.environment}-${var.service_name}-integration-test-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json
}


# Attach policy to role
resource "aws_iam_role_policy_attachment" "policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.integration_test_access_policy.arn
}