locals {
  lambda_enqueue_copy_audio = "${var.service_name}-enqueue-copy-audio"
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/lambda-product-staging/enqueue-copy-audio/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

provider "aws" {
  region = var.aws_region
}

data "aws_sqs_queue" "copy_bulk_session_asset_queue" {
  name = "${var.environment}-${var.sqs_queue_name}-queue"
}

data "aws_iam_policy_document" "sqs_copy_bulk_session_asset_send_message" {
  statement {
    effect = "Allow"
    actions = [
      "sqs:SendMessage",
      "sqs:GetQueueUrl",
    ]
    resources = [
      data.aws_sqs_queue.copy_bulk_session_asset_queue.arn
    ]
  }
}

resource "aws_iam_policy" "sqs_copy_bulk_session_asset_send_message_policy" {
  name   = "SQS-${var.environment}-copy-bulk-session-asset-enqueue-audio-asset-send-message"
  policy = data.aws_iam_policy_document.sqs_copy_bulk_session_asset_send_message.json
}

module "lambda_enqueue_copy_audio" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.5"

  environment        = var.environment
  application_family = var.application_family
  lambda_name        = local.lambda_enqueue_copy_audio

  lambda_description                             = "Begins execution for bulk session ingestion."
  lambda_function_timeout                        = "900"
  lambda_function_memory_size                    = var.lambda_memory_size
  lambda_function_reserved_concurrent_executions = var.lambda_max_concurrency
  use_container_image                            = true
  vpc_enabled                                    = true
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids

  datadog_enabled          = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT   = var.environment
    SENTRY_DSN    = module.lambda_enqueue_copy_audio_sentry.sentry_key_dsn_public_output
    OA_USER       = var.oa_user
    IDENTITY_ID   = var.identity_id
    PROFILE_ID    = var.profile_id
    PROFILE_TYPE  = var.profile_type
    SQS_QUEUE_URL = var.sqs_queue_url
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.sqs_copy_bulk_session_asset_send_message_policy.arn
  ]
}

module "lambda_enqueue_copy_audio_datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.12.0"

  environment                       = var.environment
  service_name                      = local.lambda_enqueue_copy_audio
  lambda_invocation_monitor_enabled = false
}

module "lambda_enqueue_copy_audio_sentry" {
  source = "git@github.com:theorchard/terraform-sentry//?ref=4.1.0"

  service_name       = local.lambda_enqueue_copy_audio
  environment        = var.environment
  platform           = "python"
  application_family = var.application_family
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}