terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/lambda-product-staging/integration-test/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

data "aws_caller_identity" "current" {}

data "aws_region" "current" {}

data "aws_s3_bucket" "product_staging" {
  bucket = "qa-ows-product-staging"
}

data "aws_sfn_state_machine" "validate_bulk_metadata" {
  name = "qa-sfn-validate-bulk-metadata"
}

data "aws_sfn_state_machine" "validate_bulk_asset" {
  name = "qa-sfn-validate-bulk-asset"
}

data "aws_sfn_state_machine" "bulk_session_ingest" {
  name = "qa-sfn-bulk-session-ingest"
}

# S3 Access Policy for integration tests
data "aws_iam_policy_document" "s3_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "s3:ListBucket",
    ]
    resources = [
      data.aws_s3_bucket.product_staging.arn,
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:PutObject",
      "s3:GetObject",
      "s3:DeleteObject",
      "s3:HeadObject",
      "s3:PutObjectTagging",
      "s3:GetObjectTagging",
    ]
    resources = [
      "${data.aws_s3_bucket.product_staging.arn}/*",
    ]
  }
}

resource "aws_iam_policy" "s3_policy" {
  name        = "S3-${var.environment}-${var.service_name}-integration-test-policy"
  description = "Allows integration tests to upload, verify, and delete test data in the product staging S3 bucket"
  policy      = data.aws_iam_policy_document.s3_policy_document.json
}

# Step Functions Read-Only Policy for monitoring executions
data "aws_iam_policy_document" "sfn_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "states:ListExecutions",
      "states:DescribeExecution",
      "states:GetExecutionHistory"
    ]
    # State machine ARNs required for ListExecutions
    # Execution ARNs required for DescribeExecution and GetExecutionHistory
    resources = [
      data.aws_sfn_state_machine.validate_bulk_metadata.arn,
      data.aws_sfn_state_machine.validate_bulk_asset.arn,
      data.aws_sfn_state_machine.bulk_session_ingest.arn,
      "arn:aws:states:${data.aws_region.current.id}:${data.aws_caller_identity.current.account_id}:execution:qa-sfn-validate-bulk-metadata:*",
      "arn:aws:states:${data.aws_region.current.id}:${data.aws_caller_identity.current.account_id}:execution:qa-sfn-validate-bulk-asset:*",
      "arn:aws:states:${data.aws_region.current.id}:${data.aws_caller_identity.current.account_id}:execution:qa-sfn-bulk-session-ingest:*"
    ]
  }
}

resource "aws_iam_policy" "sfn_policy" {
  name        = "StepFunctions-${var.environment}-${var.service_name}-integration-test-policy"
  description = "Allows integration tests to monitor Step Functions executions for validation and debugging"
  policy      = data.aws_iam_policy_document.sfn_policy_document.json
}

data "aws_iam_policy_document" "secrets_manager_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/ows-product-staging-integration-test/*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/lambda-product-staging-*/M2M_AUTH0_CLIENT_CREDENTIALS*",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/lambda-product-staging-*/M2M_JWT_ACCESS_TOKEN*",
    ]
  }
}

# Assume role policy used by Jenkins pipeline agent role
data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::437795906767:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

# SecretsManager Access Policy
resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-access-policy"
  policy = data.aws_iam_policy_document.secrets_manager_policy_document.json
}

# Jenkins agents will assume this role in order to access AWS resources
resource "aws_iam_role" "jenkins_invoke_role" {
  name               = "${var.environment}-${var.service_name}-role"
  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

# Attach SecretsManager access policy to Jenkins role.
resource "aws_iam_role_policy_attachment" "integration_secret_manager_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.secrets_manager_policy.arn
}

resource "aws_iam_role_policy_attachment" "integration_s3_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.s3_policy.arn
}

resource "aws_iam_role_policy_attachment" "integration_sfn_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.sfn_policy.arn
}

data "aws_lambda_function" "generate_json" {
  function_name = "qa-lambda-product-staging-generate-json"
}

data "aws_lambda_function" "set_project" {
  function_name = "qa-lambda-product-staging-set-project"
}

data "aws_lambda_function" "set_participants" {
  function_name = "qa-lambda-product-staging-set-participants"
}

data "aws_lambda_function" "set_product" {
  function_name = "qa-lambda-product-staging-set-product"
}

data "aws_iam_policy_document" "lambda_invoke_policy_document" {
  statement {
    effect  = "Allow"
    actions = ["lambda:InvokeFunction"]
    resources = [
      data.aws_lambda_function.generate_json.arn,
      data.aws_lambda_function.set_project.arn,
      data.aws_lambda_function.set_participants.arn,
      data.aws_lambda_function.set_product.arn,
    ]
  }
}

resource "aws_iam_policy" "lambda_invoke_policy" {
  name   = "Lambda-${var.environment}-${var.service_name}-integration-test-policy"
  policy = data.aws_iam_policy_document.lambda_invoke_policy_document.json
}

resource "aws_iam_role_policy_attachment" "integration_lambda_invoke_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.lambda_invoke_policy.arn
}

data "aws_sqs_queue" "copy_bulk_session_asset_queue" {
  name = "qa-copy-bulk-session-asset-queue"
}

data "aws_iam_policy_document" "sqs_copy_bulk_session_asset_send_message_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "sqs:SendMessage",
    ]
    resources = [
      data.aws_sqs_queue.copy_bulk_session_asset_queue.arn,
    ]
  }
}

resource "aws_iam_policy" "sqs_copy_bulk_session_asset_send_message_policy" {
  name        = "SQS-${var.environment}-${var.service_name}-copy-bulk-session-asset-send-message"
  description = "Allows integration tests to enqueue messages on the copy-bulk-session-asset SQS queue"
  policy      = data.aws_iam_policy_document.sqs_copy_bulk_session_asset_send_message_policy_document.json
}

resource "aws_iam_role_policy_attachment" "integration_sqs_copy_bulk_session_asset_send_message_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.sqs_copy_bulk_session_asset_send_message_policy.arn
}

data "aws_sqs_queue" "finalize_bulk_session_queue" {
  name = "qa-finalize-bulk-session-queue"
}

data "aws_iam_policy_document" "sqs_finalize_bulk_session_send_message_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "sqs:SendMessage",
    ]
    resources = [
      data.aws_sqs_queue.finalize_bulk_session_queue.arn,
    ]
  }
}

resource "aws_iam_policy" "sqs_finalize_bulk_session_send_message_policy" {
  name        = "SQS-${var.environment}-${var.service_name}-finalize-bulk-session-send-message"
  description = "Allows integration tests to enqueue messages on the finalize-bulk-session SQS queue"
  policy      = data.aws_iam_policy_document.sqs_finalize_bulk_session_send_message_policy_document.json
}

resource "aws_iam_role_policy_attachment" "integration_sqs_finalize_bulk_session_send_message_policy_attachment" {
  role       = aws_iam_role.jenkins_invoke_role.id
  policy_arn = aws_iam_policy.sqs_finalize_bulk_session_send_message_policy.arn
}