# Copy Bulk Session Asset Step Function.
data "aws_caller_identity" "current" {}

provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/sfn-copy-bulk-session-asset/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_lambda_function" "begin_copy_asset_lambda" {
  function_name = "${var.environment}-lambda-product-staging-begin-copy-asset"
}

data "aws_lambda_function" "copy_asset_lambda" {
  function_name = "${var.environment}-lambda-product-staging-copy-asset"
}

data "aws_lambda_function" "poll_asset_status_lambda" {
  function_name = "${var.environment}-lambda-product-staging-poll-asset-status"
}

data "aws_lambda_function" "handle_asset_copy_success_lambda" {
  function_name = "${var.environment}-lambda-product-staging-handle-asset-success"
}

data "aws_lambda_function" "handle_asset_copy_failure_lambda" {
  function_name = "${var.environment}-lambda-product-staging-handle-asset-copy-failure"
}

# Policy for lambda invocation initiated by state machine.
data "aws_iam_policy_document" "assume_role_for_state_machine_policy" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "Service"

      identifiers = [
        "states.${var.aws_region}.amazonaws.com",
      ]
    }
  }
}

# States role for lambda invocation
resource "aws_iam_role" "invoke_lambdas_role_for_state_machine" {
  name               = "${var.environment}-copy-bulk-session-asset-invoke-lambdas-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_for_state_machine_policy.json
}

data "aws_iam_policy_document" "invoke_lambda_policy_for_state_machine" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction",
    ]
    resources = [
      data.aws_lambda_function.begin_copy_asset_lambda.arn,
      data.aws_lambda_function.copy_asset_lambda.arn,
      data.aws_lambda_function.poll_asset_status_lambda.arn,
      data.aws_lambda_function.handle_asset_copy_success_lambda.arn,
      data.aws_lambda_function.handle_asset_copy_failure_lambda.arn
    ]
  }
}

resource "aws_iam_role_policy" "invoke_lambda_role_policy" {
  name   = "${var.environment}-copy-bulk-session-asset-invoke-lambdas-role-policy"
  role   = aws_iam_role.invoke_lambdas_role_for_state_machine.id
  policy = data.aws_iam_policy_document.invoke_lambda_policy_for_state_machine.json
}

data "template_file" "state_machine_definition" {
  template = file("${path.module}/stepfunction.asl.json")

  vars = {
    begin_copy_asset_lambda_arn          = data.aws_lambda_function.begin_copy_asset_lambda.arn,
    copy_asset_lambda_arn                = data.aws_lambda_function.copy_asset_lambda.arn,
    poll_asset_status_lambda_arn         = data.aws_lambda_function.poll_asset_status_lambda.arn,
    handle_asset_copy_success_lambda_arn = data.aws_lambda_function.handle_asset_copy_success_lambda.arn,
    handle_asset_copy_failure_lambda_arn = data.aws_lambda_function.handle_asset_copy_failure_lambda.arn
  }
}

resource "aws_sfn_state_machine" "state_machine" {
  name       = "${var.environment}-${var.state_machine_name}"
  role_arn   = aws_iam_role.invoke_lambdas_role_for_state_machine.arn
  definition = data.template_file.state_machine_definition.rendered

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.state_machine_name
    terraformed        = true
  }

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }
}

# Policy document that lets other things invoke this sfn
data "aws_iam_policy_document" "invoke_sfn_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "states:StartExecution",
      "states:ListExecutions"
    ]

    resources = [
      aws_sfn_state_machine.state_machine.arn
    ]
  }
}

# Policy that uses the policy document
resource "aws_iam_policy" "invoke_sfn_policy" {
  name        = "StepFunctions-${var.environment}-${var.state_machine_name}-StartExecution"
  policy      = data.aws_iam_policy_document.invoke_sfn_policy_document.json
  description = "Policy that allows invoking the copy bulk session asset sfn."
}

# Attach the policy to the assumed role
resource "aws_iam_role_policy_attachment" "invoke_sfn_policy_attachment" {
  role       = aws_iam_role.invoke_lambdas_role_for_state_machine.id
  policy_arn = aws_iam_policy.invoke_sfn_policy.arn
}

module "m2m_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//modules/auth0m2m?ref=1.6.1"

  environment        = var.environment
  service_name       = var.state_machine_name
  application_family = var.application_family
}