locals {
  lambda_validate_image = "${var.service_name}-validate-image"
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/lambda-product-staging/validate-image/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

provider "aws" {
  region = var.aws_region
}

data "aws_s3_bucket" "product_staging_bucket" {
  bucket = "${var.environment}-ows-product-staging"
}

data "aws_iam_policy_document" "product_staging_validate_image_bucket_read_access_document" {
  statement {
    effect = "Allow"
    actions = [
      "s3:GetObject"
    ]
    resources = [
      "${data.aws_s3_bucket.product_staging_bucket.arn}/*",
    ]
  }
}

resource "aws_iam_policy" "product_staging_validate_image_bucket_ro_policy" {
  name   = "S3-${data.aws_s3_bucket.product_staging_bucket.bucket}-validate-image-RO"
  policy = data.aws_iam_policy_document.product_staging_validate_image_bucket_read_access_document.json
}

module "lambda_validate_image" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.5"

  environment        = var.environment
  application_family = var.application_family
  lambda_name        = local.lambda_validate_image

  lambda_description                             = "Examines an image asset to see if it is valid for our ingestion criteria."
  lambda_function_timeout                        = "900"
  lambda_function_memory_size                    = var.lambda_memory_size
  lambda_function_reserved_concurrent_executions = var.lambda_max_concurrency
  use_container_image                            = true
  vpc_enabled                                    = true
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids

  datadog_enabled          = true
  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT  = var.environment
    SENTRY_DSN   = module.lambda_validate_image_sentry.sentry_key_dsn_public_output
    IDENTITY_ID  = var.identity_id
    PROFILE_ID   = var.profile_id
    PROFILE_TYPE = var.profile_type
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.product_staging_validate_image_bucket_ro_policy.arn
  ]
}

module "lambda_validate_image_datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.12.0"

  environment                       = var.environment
  service_name                      = local.lambda_validate_image
  lambda_invocation_monitor_enabled = false
}

module "lambda_validate_image_sentry" {
  source = "git@github.com:theorchard/terraform-sentry//?ref=4.1.0"

  service_name       = local.lambda_validate_image
  environment        = var.environment
  platform           = "python"
  application_family = var.application_family
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}