provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/lambda-smart-downloader/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_iam_policy" "existing_swf_policies" {
  for_each = toset(local.existing_swf_policy_names)
  name     = each.value
}

module "vpc_info" {
  source      = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.2.2"
  environment = var.environment
}

locals {
  // we want to extract dynamodb stream name from the arn
  path_parts           = split("/", module.dynamodb_table_tasks.aws_dynamodb_table_stream_arn)
  dynamodb_stream_name = local.path_parts[length(local.path_parts) - 1]
}

module "lambda_smart_downloader" {
  source                                         = "git@github.com:theorchard/terraform-lambda.git//?ref=4.3.0"
  lambda_name                                    = var.lambda_name
  lambda_description                             = "Lambda Smart Downloader from lambda-data-ingestion repo"
  environment                                    = var.environment
  application_family                             = var.application_family
  vpc_enabled                                    = true
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids
  datadog_enabled                                = true
  datadog_advanced_enabled                       = true
  datadog_advanced_trace_enabled                 = false
  use_container_image                            = true
  splitio_enabled                                = false
  lambda_function_memory_size                    = 10240
  lambda_function_timeout                        = 600
  lambda_function_reserved_concurrent_executions = 200

  event_source_mapping_enabled                       = true
  event_source_mapping_resource_type                 = "dynamodb"
  event_source_mapping_stream_name                   = local.dynamodb_stream_name
  event_source_mapping_table_name                    = module.dynamodb_table_tasks.aws_dynamodb_table_id
  event_source_mapping_starting_position             = "LATEST"
  event_source_mapping_batch_size                    = 10
  event_source_mapping_batch_window                  = 3
  event_source_mapping_parallelization_factor        = 10
  event_source_mapping_maximum_record_age_in_seconds = 600
  event_source_mapping_maximum_retry_attempts        = 0



  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment
    SENTRY_DSN  = module.sentry.sentry_key_dsn_public_output
  }

  iam_managed_policy_attachments = concat(
    [for policy in data.aws_iam_policy.existing_swf_policies : policy.arn],
    [aws_iam_policy.dynamodb_rw_policy.arn]
  )
}

module "dynamodb_table_tasks" {
  source = "git@github.com:theorchard/terraform-dynamodb.git//?ref=3.3.1"

  env                = var.environment
  table_name         = "smart_downloader_tasks"
  application_family = var.application_family
  hash_key           = "partition"
  view_type          = "NEW_IMAGE"
  ttl_attribute_name = "ttl"
  ttl_enabled        = true

  use_on_demand = true

  attribute = [
    {
      name = "partition"
      type = "S"
    },
    {
      name = "jobId"
      type = "S"
    },
  ]

  global_secondary_index = [
    {
      name            = "jobId-index"
      hash_key        = "jobId"
      projection_type = "ALL"
    }
  ]
}

data "aws_iam_policy_document" "dynamodb_table_rw_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "dynamodb:GetItem",
      "dynamodb:PutItem",
      "dynamodb:BatchWriteItem",
      "dynamodb:UpdateItem",
      "dynamodb:DeleteItem",
      "dynamodb:Query",
      "dynamodb:Scan",
    ]
    resources = [
      module.dynamodb_table_tasks.aws_dynamodb_table_arn,
      "${module.dynamodb_table_tasks.aws_dynamodb_table_arn}/index/jobId-index",
    ]
  }
}

resource "aws_iam_policy" "dynamodb_rw_policy" {
  name   = "dynamodb-table-${module.dynamodb_table_tasks.aws_dynamodb_table_id}-RW-policy"
  policy = data.aws_iam_policy_document.dynamodb_table_rw_policy_document.json
}

module "sentry" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"
  service_name       = var.lambda_name
  environment        = var.environment
  application_family = var.application_family
  platform           = "python"
}

module "lambda_datadog_integration" {
  source       = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.9"
  environment  = var.environment
  service_name = var.lambda_name
}